mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-28 22:57:37 +00:00
removed extra/boost1.69
This commit is contained in:
Kevin Mihelich
parent
a6258090fb
commit
b42ce5f43a
1 changed files with 0 additions and 147 deletions
|
|
@ -1,147 +0,0 @@
|
|||
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
|
||||
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
|
||||
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
||||
# Contributor: Marius Knaust <marius.knaust@gmail.com>
|
||||
# Contributor: Ionut Biru <ibiru@archlinux.org>
|
||||
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
|
||||
# Contributor: kevin <kevin@archlinux.org>
|
||||
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
|
||||
# Contributor: Kritoke <kritoke@gamebox.net>
|
||||
# Contributor: Luca Roccia <little_rock@users.sourceforge.net>
|
||||
|
||||
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
||||
# - changed _bindir to .linuxarm from .linuxx86
|
||||
# - build armv6h with -march=armv6k
|
||||
# - specify arm architecture to b2 for aarch64
|
||||
|
||||
pkgbase=boost1.69
|
||||
pkgname=('boost1.69-libs' 'boost1.69')
|
||||
pkgver=1.69.0
|
||||
_boostver=${pkgver//./_}
|
||||
pkgrel=4
|
||||
url='https://www.boost.org/'
|
||||
arch=('x86_64')
|
||||
license=('custom')
|
||||
makedepends=('icu' 'python' 'python2' 'python-numpy' 'python2-numpy' 'bzip2' 'zlib' 'openmpi')
|
||||
source=(https://downloads.sourceforge.net/project/boost/boost/${pkgver}/boost_${_boostver}.tar.bz2)
|
||||
sha256sums=('8f32d4617390d1c2d16f26a27ab60d97807b35440d45891fa340fc2648b04406')
|
||||
|
||||
# ************************************************************************* #
|
||||
# Temporary package added for building mapnik; should NOT be used elsewhere #
|
||||
# ************************************************************************* #
|
||||
|
||||
build() {
|
||||
CFLAGS=`echo $CFLAGS | sed -e 's/armv6/armv6k/'` && CXXFLAGS="$CFLAGS"
|
||||
export _stagedir="${srcdir}/stagedir"
|
||||
local JOBS="$(sed -e 's/.*\(-j *[0-9]\+\).*/\1/' <<< ${MAKEFLAGS})"
|
||||
|
||||
cd boost_${_boostver}
|
||||
|
||||
./bootstrap.sh --with-toolset=gcc --with-icu --with-python=/usr/bin/python2
|
||||
|
||||
_bindir="bin.linuxarm"
|
||||
install -Dm755 tools/build/src/engine/$_bindir/b2 "${_stagedir}"/bin/b2
|
||||
|
||||
# Support for OpenMPI
|
||||
echo "using mpi ;" >> project-config.jam
|
||||
|
||||
# boostbook is needed by quickbook
|
||||
install -dm755 "${_stagedir}"/share/boostbook
|
||||
cp -a tools/boostbook/{xsl,dtd} "${_stagedir}"/share/boostbook/
|
||||
|
||||
# default "minimal" install: "release link=shared,static
|
||||
# runtime-link=shared threading=single,multi"
|
||||
# --layout=tagged will add the "-mt" suffix for multithreaded libraries
|
||||
# and installs includes in /usr/include/boost.
|
||||
# --layout=system no longer adds the -mt suffix for multi-threaded libs.
|
||||
# install to ${_stagedir} in preparation for split packaging
|
||||
"${_stagedir}"/bin/b2 \
|
||||
architecture=arm \
|
||||
variant=release \
|
||||
debug-symbols=off \
|
||||
threading=multi \
|
||||
runtime-link=shared \
|
||||
link=shared,static \
|
||||
toolset=gcc \
|
||||
python=2.7 \
|
||||
cflags="${CPPFLAGS} ${CFLAGS} -fPIC -O3" \
|
||||
cxxflags="${CPPFLAGS} ${CXXFLAGS} -std=c++14 -fPIC -O3" \
|
||||
linkflags="${LDFLAGS}" \
|
||||
--layout=system \
|
||||
${JOBS} \
|
||||
\
|
||||
--prefix="${_stagedir}" \
|
||||
install
|
||||
|
||||
# because b2 in boost 1.62.0 doesn't seem to respect python parameter, we
|
||||
# need another run for liboost_python3.so
|
||||
|
||||
./bootstrap.sh --with-toolset=gcc --with-icu --with-python=/usr/bin/python3 \
|
||||
--with-libraries=python
|
||||
|
||||
"${_stagedir}"/bin/b2 clean
|
||||
"${_stagedir}"/bin/b2 \
|
||||
variant=release \
|
||||
debug-symbols=off \
|
||||
threading=multi \
|
||||
runtime-link=shared \
|
||||
link=shared,static \
|
||||
toolset=gcc \
|
||||
python=3.8 \
|
||||
cflags="${CPPFLAGS} ${CFLAGS} -fPIC -O3" \
|
||||
cxxflags="${CPPFLAGS} ${CXXFLAGS} -std=c++14 -fPIC -O3" \
|
||||
linkflags="${LDFLAGS}" \
|
||||
--layout=system \
|
||||
${JOBS} \
|
||||
\
|
||||
--prefix="${_stagedir}/python3" \
|
||||
--with-python \
|
||||
install
|
||||
}
|
||||
|
||||
package_boost1.69() {
|
||||
pkgdesc='Free peer-reviewed portable C++ source libraries - development headers'
|
||||
depends=("boost1.69-libs=${pkgver}")
|
||||
conflicts=('boost')
|
||||
optdepends=('python: for python bindings'
|
||||
'python2: for python2 bindings')
|
||||
options=('staticlibs')
|
||||
|
||||
install -dm755 "${pkgdir}"/usr
|
||||
cp -a "${_stagedir}"/{bin,include,share} "${pkgdir}"/usr
|
||||
|
||||
install -d "${pkgdir}"/usr/lib
|
||||
cp -a "${_stagedir}"/lib/*.a "${pkgdir}"/usr/lib/
|
||||
cp -a "${_stagedir}"/lib/libboost_*.so "${pkgdir}"/usr/lib/
|
||||
|
||||
install -Dm644 "${srcdir}/"boost_${_boostver}/LICENSE_1_0.txt \
|
||||
"${pkgdir}"/usr/share/licenses/boost1.69/LICENSE_1_0.txt
|
||||
|
||||
install -Dm644 "${_stagedir}"/python3/lib/libboost_*.a \
|
||||
"${pkgdir}"/usr/lib/
|
||||
|
||||
ln -s /usr/bin/b2 "$pkgdir"/usr/bin/bjam
|
||||
}
|
||||
|
||||
package_boost1.69-libs() {
|
||||
pkgdesc='Free peer-reviewed portable C++ source libraries - runtime libraries'
|
||||
depends=('bzip2' 'zlib' 'icu')
|
||||
optdepends=('openmpi: for mpi support')
|
||||
provides=('libboost_context.so')
|
||||
|
||||
install -dm755 "${pkgdir}"/usr
|
||||
cp -a "${_stagedir}"/lib "${pkgdir}"/usr
|
||||
cp -a "${_stagedir}"/python3/lib/libboost_* "${pkgdir}"/usr/lib
|
||||
rm "${pkgdir}"/usr/lib/*.a
|
||||
|
||||
# remove library symlinks shipped in boost1.69 / conflicting with boost-libs
|
||||
rm "${pkgdir}"/usr/lib/libboost_*.so
|
||||
|
||||
# remove mpi.so module which conflicts with boost
|
||||
rm "${pkgdir}"/usr/lib/mpi.so
|
||||
|
||||
install -Dm644 "${srcdir}/"boost_${_boostver}/LICENSE_1_0.txt \
|
||||
"${pkgdir}"/usr/share/licenses/boost1.69-libs/LICENSE_1_0.txt
|
||||
}
|
||||
|
||||
# vim: ts=2 sw=2 et:
|
||||
Loading…
Reference in a new issue