added core/nspr

core/nspr/PKGBUILD

@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+# Contributor: Alexander Baldeck <alexander@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - --enable-64bit for AArch64
+
+pkgname=nspr
+pkgver=4.10.8
+pkgrel=1
+pkgdesc="Netscape Portable Runtime"
+arch=(i686 x86_64)
+url="http://www.mozilla.org/projects/nspr/"
+license=('MPL' 'GPL')
+depends=('glibc')
+makedepends=('zip')
+options=('!emptydirs')
+source=(ftp://ftp.mozilla.org/pub/mozilla.org/nspr/releases/v${pkgver}/src/${pkgname}-${pkgver}.tar.gz)
+sha1sums=('c87c6a10e0e36866006b45c194d70cd8c67d0934')
+sha256sums=('507ea57c525c0c524dae4857a642b4ef5c9d795518754c7f83422d22fe544a15')
+
+build() {
+  cd $pkgname-$pkgver
+
+  if [ "$CARCH" = "x86_64" -o "$CARCH" = "aarch64" ]; then
+    _confflags="--enable-64bit"
+  else
+    _confflags=""
+  fi
+
+  ./nspr/configure \
+      --prefix=/usr \
+      --libdir=/usr/lib \
+      --includedir=/usr/include/nspr \
+      --enable-optimize \
+      --disable-debug ${_confflags}
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+
+  ln -s nspr.pc "$pkgdir/usr/lib/pkgconfig/mozilla-nspr.pc"
+  rm -r "$pkgdir"/usr/bin/{compile-et.pl,prerr.properties} \
+         "$pkgdir/usr/include/nspr/md"
+}