archlinuxarm/PKGBUILDs
1
0
Fork 0
mirror of https://github.com/archlinuxarm/PKGBUILDs.git synced 2025-03-19 00:21:40 +00:00
Code Issues Projects Releases Packages Wiki Activity Actions

Merge pull request #429 from aldrik/ghc

Browse source 
extra/ghc 7.6.2-1
This commit is contained in:
Mike Brown 2013-03-23 05:57:46 -07:00
commit bb89c41f74
5 changed files with 480 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

191
extra/ghc/PKGBUILD Normal file
View file

@ -0,0 +1,191 @@
# $Id: PKGBUILD 168343 2012-10-09 04:08:52Z tdziedzic $
# Maintainer: Thomas Dziedzic <gostrc@gmail.com>
# Maintainer: Vesa Kaihlavirta <vesa@archlinux.org>
# Special note for devs looking to upgrade this package:
# ghc places a unique hash for each library when it is built.
# Libraries depend on versions specified by those hashes.
# This implies that all libraries need to be rebuilt when ghc is rebuilt.
# ALARM: David Flemström <david.flemstrom@gmail.com>
# - Add patch for vfp flags (add-vfp-flags.patch)
# - Change build.mk to use the LLVM backend with the right
# optimization passes
# - Add LLVM as a dependency
# - Correct gcc path after bulding with distcc
# - Uncommented !makeflags option
# - Use debian package for the initial build
buildarch=1
pkgname=ghc
pkgver=7.6.2
pkgrel=1
pkgdesc='The Glasgow Haskell Compiler'
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h')
url='http://www.haskell.org/ghc/'
license=('custom')
# libffi might be needed in the future: http://hackage.haskell.org/trac/ghc/ticket/4496
depends=('llvm' 'perl' 'gmp>=5.0' 'gcc') # 'libffi')
makedepends=('ghc' 'perl' 'libxslt' 'docbook-xsl')
checkdepends=('python2')
install='ghc.install'
# keep this otherwise a lot of tests will show as unexpected failures... need to investigate why using -jn for n > 1 does this...
options=('!makeflags')
# missing rtl?
provides=('haskell-array=0.4.0.1'
'haskell-base=4.6.0.1'
'haskell-binary=0.5.1.1'
'haskell-bin-package-db=0.0.0.0'
'haskell-bytestring=0.10.0.2'
'haskell-containers=0.5.0.0'
'haskell-deepseq=1.3.0.1'
'haskell-directory=1.2.0.1'
'haskell-filepath=1.3.0.1'
'haskell-ghc-prim=0.3.0.0'
'haskell-haskell2010=1.1.1.0'
'haskell-haskell98=2.0.0.2'
'haskell-hoopl=3.9.0.0'
'haskell-hpc=0.6.0.0'
'haskell-integer-gmp=0.5.0.0'
'haskell-old-locale=1.0.0.5'
'haskell-old-time=1.1.0.1'
'haskell-pretty=1.1.1.0'
'haskell-process=1.1.0.2'
'haskell-template-haskell=2.8.0.0'
'haskell-time=1.4.0.1'
'haskell-unix=2.6.0.1'
'haskell-cabal=1.16.0'
)
replaces=('haskell-array<0.4.0.1'
'haskell-base<4.6.0.1'
'haskell-binary<0.5.1.1'
'haskell-bin-package-db<0.0.0.0'
'haskell-bytestring<0.10.0.2'
'haskell-containers<0.5.0.0'
'haskell-deepseq<1.3.0.1'
'haskell-directory<1.2.0.1'
'haskell-filepath<1.3.0.1'
'haskell-ghc-prim<0.3.0.0'
'haskell-haskell2010<1.1.1.0'
'haskell-haskell98<2.0.0.2'
'haskell-hoopl<3.9.0.0'
'haskell-hpc<0.6.0.0'
'haskell-integer-gmp<0.5.0.0'
'haskell-old-locale<1.0.0.5'
'haskell-old-time<1.1.0.1'
'haskell-pretty<1.1.1.0'
'haskell-process<1.1.0.2'
'haskell-template-haskell<2.8.0.0'
'haskell-time<1.4.0.1'
'haskell-unix<2.6.0.1'
'haskell-cabal<1.16.0'
)
source=("http://www.haskell.org/ghc/dist/${pkgver}/ghc-${pkgver}-src.tar.bz2"
"http://www.haskell.org/ghc/dist/${pkgver}/ghc-${pkgver}-testsuite.tar.bz2"
'build.mk'
'add-vfp-flags.patch')
md5sums=('2585d83e7d8daece2fe0949c6bc42a2c'
'8454aaeb4e226ddb66c237c15874a47f'
'cb89e280f907c60791d08613f05ec049'
'de3d0a2ae5330459481b33584f15a1cd')
build() {
cd ghc-${pkgver}
cp ${srcdir}/build.mk mk/build.mk
patch -p1 < ${srcdir}/add-vfp-flags.patch
# have to 're-boot' because the patch changes configure stuff
./boot
./configure \
--prefix=/usr
make
}
check() {
# keep this otherwise a lot of tests will show as unexpected failures... need to investigate why using -jn for n > 1 does this...
unset MAKEFLAGS
cd ghc-${pkgver}
# python2 rename
sed -e 's/PYTHON = python/&2/' -i testsuite/mk/boilerplate.mk
sed -e 's_#!/usr/bin/env python_&2_' -i testsuite/timeout/calibrate testsuite/timeout/timeout.py
# upstream known failures on both i686 and x86_64:
# ghci.debugger/scripts break011 [bad stderr] (ghci)
# perf/compiler parsing001 [stat not good enough] (normal)
# simplCore/should_compile spec-inline [stderr mismatch] (optasm)
# upstream known failures on i686 only:
# numrun012 test fails on i686 works on x86_64 - http://hackage.haskell.org/trac/ghc/ticket/5856
make test
# enabling threads to speed up
# causes more failures than make test, need to investigate
# upstream known failures on both i686 and x86_64:
# perf/compiler parsing001 [stat not good enough] (normal)
# simplCore/should_compile spec-inline [stderr mismatch] (optasm)
# upstream known failures on i686 only:
# numrun012 test fails on i686 works on x86_64 - http://hackage.haskell.org/trac/ghc/ticket/5856
#make THREADS=9 test
# will most likely cause lots of failures
# enable this when upstream has 0 test failures from a simple 'make test'
# zero unexpected failures on all tier 1 platforms - http://hackage.haskell.org/trac/ghc/ticket/5757
#make fulltest
}
package() {
cd ghc-${pkgver}
make DESTDIR=${pkgdir} install
install -d ${pkgdir}/usr/share/licenses/ghc
install -m644 LICENSE \
${pkgdir}/usr/share/licenses/ghc
sed -r 's|("C compiler command", ")[^"]+|\1/usr/bin/gcc|' \
-i "${pkgdir}/usr/lib/ghc-${pkgver}/settings"
}
# Chicken and egg fix
if ! pacman -Ssq ^ghc$ > /dev/null; then
makedepends=("${makedepends[@]:1}" "ncurses")
if [ "${CARCH}" = "armv7h" ]; then
source+=("http://ftp.uk.debian.org/debian/pool/main/g/ghc/ghc_7.6.2-1_armhf.deb")
md5sums+=("5d7190b3cc48771019b47376d1e69a1c")
elif [ "${CARCH}" = "armv6h" ]; then
source+=("http://downloads.raspberrypi.org/raspbian/raspbian/pool/main/g/ghc/ghc_7.4.1-4+rpi1_armhf.deb")
md5sums+=("79c70db16e69b5617a3761e735db0f42")
else
source+=("http://ftp.uk.debian.org/debian/pool/main/g/ghc/ghc_7.6.2-1_armel.deb")
md5sums+=("69894b056a12a608bd4d454ffbe30d9c")
fi
eval "$(echo "_build()"; declare -f build | tail -n +2)"
build() {
if [ "${CARCH}" = "armv7h" ]; then
ar x "ghc_7.6.2-1_armhf.deb"
elif [ "${CARCH}" = "armv6h" ]; then
ar x "ghc_7.4.1-4+rpi1_armhf.deb"
else
ar x "ghc_7.6.2-1_armel.deb"
fi
rm -rf usr var
tar -zxf data.tar.gz
sed "s|\"/|\"${srcdir}/|" -i usr/lib/ghc/bin/ghc{,-pkg}
sed "s| /usr| ${srcdir}/usr|" -i var/lib/ghc/package.conf.d/*
sed "s/-3.0//" -i usr/lib/ghc/settings # correct LLVM commands
ln -s /usr/lib/libffi.so.6 usr/lib/libffi.so.5
ln -s /usr/lib/libncurses.so.5 usr/lib/libtinfo.so.5
ln -fs ../../../var/lib/ghc/package.conf.d usr/lib/ghc/package.conf.d
export PATH="${PATH}:${srcdir}/usr/lib/ghc/bin"
export LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${srcdir}/usr/lib"
ghc-pkg recache
_build
}
fi

41
extra/ghc/add-vfp-flags.patch Normal file
View file

@ -0,0 +1,41 @@
diff --git a/aclocal.m4 b/aclocal.m4
index 127f528..a2db986 100644
--- a/aclocal.m4
+++ b/aclocal.m4
@@ -344,12 +344,12 @@
[AC_DEFINE(arm_HOST_ARCH_PRE_ARMv7, 1, [ARM pre v7])
changequote(, )dnl
ARM_ISA=ARMv6
- ARM_ISA_EXT="[]"
+ ARM_ISA_EXT="[VFPv2]"
changequote([, ])dnl
],
[changequote(, )dnl
ARM_ISA=ARMv7
- ARM_ISA_EXT="[VFPv3,NEON]"
+ ARM_ISA_EXT="[VFPv3D16]"
changequote([, ])dnl
])
])
diff --git a/compiler/main/DriverPipeline.hs b/compiler/main/DriverPipeline.hs
index b128c1f..c71546c 100644
--- a/compiler/main/DriverPipeline.hs
+++ b/compiler/main/DriverPipeline.hs
@@ -1453,14 +1453,17 @@ runPhase LlvmLlc input_fn dflags
else if (elem VFPv3D16 ext)
then ["-mattr=+v7,+vfp3,+d16"]
else []
+ ArchARM ARMv6 ext _ -> if (elem VFPv2 ext)
+ then ["-mattr=+v6,+vfp2"]
+ else ["-mattr=+v6"]
_ -> []
-- On Ubuntu/Debian with ARM hard float ABI, LLVM's llc still
-- compiles into soft-float ABI. We need to explicitly set abi
-- to hard
abiOpts = case platformArch (targetPlatform dflags) of
- ArchARM ARMv7 _ HARD -> ["-float-abi=hard"]
- ArchARM ARMv7 _ _ -> []
- _ -> []
+ ArchARM _ _ HARD -> ["-float-abi=hard"]
+ ArchARM _ _ _ -> []
+ _ -> []

200
extra/ghc/build.mk Normal file
View file

@ -0,0 +1,200 @@
# -----------------------------------------------------------------------------
# A Sample build.mk
#
# Uncomment one of the following BuildFlavour settings to get the desired
# overall build type, and then tweak the options in the relevant section
# below.
# Uncomment one of these to select a build profile below:
# Full build with max optimisation and everything enabled (very slow build)
#BuildFlavour = perf
# As above but build GHC using the LLVM backend
BuildFlavour = perf-llvm
# Fast build with optimised libraries, no profiling (RECOMMENDED):
#BuildFlavour = quick
# Even faster build. NOT RECOMMENDED: the libraries will be
# completely unoptimised, so any code built with this compiler
# (including stage2) will run very slowly:
#BuildFlavour = quickest
# Profile the stage2 compiler:
#BuildFlavour = prof
# A development build, working on the stage 1 compiler:
#BuildFlavour = devel1
# A development build, working on the stage 2 compiler:
#BuildFlavour = devel2
# An unregisterised, optimised build of ghc, for porting:
#BuildFlavour = unreg
GhcLibWays = v
# -------- 1. A Performance/Distribution build--------------------------------
ifeq "$(BuildFlavour)" "perf"
# perf matches the default settings, repeated here for comparison:
SRC_HC_OPTS = -O -H64m
GhcStage1HcOpts = -O -fasm
GhcStage2HcOpts = -O2 -fasm
GhcHcOpts = -Rghc-timing
GhcLibHcOpts = -O2
GhcLibWays += p
ifeq "$(PlatformSupportsSharedLibs)" "YES"
GhcLibWays += dyn
endif
endif
# ---------------- Perf build using LLVM -------------------------------------
ifeq "$(BuildFlavour)" "perf-llvm"
SRC_HC_OPTS = -O -H64m -fllvm
GhcStage1HcOpts = -O -fllvm
GhcStage2HcOpts = -O2 -fllvm
GhcHcOpts = -Rghc-timing
GhcLibHcOpts = -O2
GhcLibWays += p
ifeq "$(PlatformSupportsSharedLibs)" "YES"
GhcLibWays += dyn
endif
endif
# -------- A Fast build ------------------------------------------------------
ifeq "$(BuildFlavour)" "quickest"
SRC_HC_OPTS = -H64m -O0 -fasm
GhcStage1HcOpts = -O -fasm
GhcStage2HcOpts = -O0 -fasm
GhcLibHcOpts = -O0 -fasm
SplitObjs = NO
HADDOCK_DOCS = NO
BUILD_DOCBOOK_HTML = NO
BUILD_DOCBOOK_PS = NO
BUILD_DOCBOOK_PDF = NO
endif
# -------- A Fast build with optimised libs ----------------------------------
ifeq "$(BuildFlavour)" "quick"
SRC_HC_OPTS = -H64m -O0 -fasm
GhcStage1HcOpts = -O -fasm
GhcStage2HcOpts = -O0 -fasm
GhcLibHcOpts = -O -fasm
SplitObjs = NO
HADDOCK_DOCS = NO
BUILD_DOCBOOK_HTML = NO
BUILD_DOCBOOK_PS = NO
BUILD_DOCBOOK_PDF = NO
endif
# -------- Profile the stage2 compiler ---------------------------------------
ifeq "$(BuildFlavour)" "prof"
SRC_HC_OPTS = -H64m -O0 -fasm
GhcStage1HcOpts = -O -fasm
GhcStage2HcOpts = -O -fasm
GhcLibHcOpts = -O -fasm
GhcLibWays += p
GhcProfiled = YES
SplitObjs = NO
HADDOCK_DOCS = NO
BUILD_DOCBOOK_HTML = NO
BUILD_DOCBOOK_PS = NO
BUILD_DOCBOOK_PDF = NO
endif
# -------- A Development build (stage 1) -------------------------------------
ifeq "$(BuildFlavour)" "devel1"
SRC_HC_OPTS = -H64m -O -fasm
GhcLibHcOpts = -O -dcore-lint
GhcStage1HcOpts = -Rghc-timing -O0 -DDEBUG
GhcStage2HcOpts = -Rghc-timing -O -fasm
SplitObjs = NO
HADDOCK_DOCS = NO
BUILD_DOCBOOK_HTML = NO
BUILD_DOCBOOK_PS = NO
BUILD_DOCBOOK_PDF = NO
LAX_DEPENDENCIES = YES
endif
# -------- A Development build (stage 2) -------------------------------------
ifeq "$(BuildFlavour)" "devel2"
SRC_HC_OPTS = -H64m -O -fasm
GhcLibHcOpts = -O -dcore-lint
GhcStage1HcOpts = -Rghc-timing -O -fasm
GhcStage2HcOpts = -Rghc-timing -O0 -DDEBUG
SplitObjs = NO
HADDOCK_DOCS = NO
BUILD_DOCBOOK_HTML = NO
BUILD_DOCBOOK_PS = NO
BUILD_DOCBOOK_PDF = NO
LAX_DEPENDENCIES = YES
# After stage 1 and the libraries have been built, you can uncomment this line:
# stage=2
# Then stage 1 will not be touched by the build system, until
# you comment the line again. This is a useful trick for when you're
# working on stage 2 and want to freeze stage 1 and the libraries for
# a while.
endif
# -------- A Unregisterised build) -------------------------------------------
ifeq "$(BuildFlavour)" "unreg"
# Note that the LLVM backend works in unregisterised mode as well as
# registerised mode. This often makes it a good choice for porting
# GHC.
GhcUnregisterised = YES
GhcWithNativeCodeGen = NO
SRC_HC_OPTS = -O -H64m # -fllvm
GhcStage1HcOpts = -O
GhcStage2HcOpts = -O2
GhcHcOpts = -Rghc-timing
GhcLibHcOpts = -O2
SplitObjs = NO
HADDOCK_DOCS = NO
BUILD_DOCBOOK_HTML = NO
BUILD_DOCBOOK_PS = NO
BUILD_DOCBOOK_PDF = NO
endif
# -----------------------------------------------------------------------------
# Other settings that might be useful
# NoFib settings
NoFibWays =
STRIP_CMD = :

10
extra/ghc/ghc.install Normal file
View file

@ -0,0 +1,10 @@
pre_upgrade() {
echo '==> Unregistering cabalized packages...'
[[ -d /usr/share/haskell ]] && find /usr/share/haskell -maxdepth 2 -name 'unregister.sh' -exec {} \;
echo '==> Done.'
}
post_upgrade() {
echo '==> All cabalized packages need to be reinstalled now.'
echo '==> See /usr/share/haskell/ and ghc-pkg list --user for a tentative list of affected packages.'
}

38
extra/ghc/print-provides-replaces.sh Executable file
View file

@ -0,0 +1,38 @@
#!/bin/bash
. PKGBUILD
if [[ ! -d src/ghc-${pkgver}/libraries ]]; then
echo "error: no directory src/ghc-${pkgver}/libraries: You must extract the source tarball under src/"
exit 1
fi
declare -A exclude
# no Win32 cause we're not building on windows
exclude['Win32']=1
# no integer-simple because we use integer-gmp
exclude['integer-simple']=1
# extract excluded libraries from ghc.mk
for exclude_pkg in $(sed 's/PKGS_THAT_ARE_INTREE_ONLY := //p' -n src/ghc-${pkgver}/ghc.mk); do
exclude[${exclude_pkg}]=1
done
cd src/ghc-${pkgver}/libraries
# $1 is the name of the variable
# $2 is the string for the test, either '=' or '<'
print_var() {
printf "$1=("
for pkg in $(ls ./*/*.cabal | awk -F '/' '{ print $2 }'); do
[[ ${exclude[${pkg}]} ]] && continue
version=$(awk 'tolower($0) ~ /^version:/ {print $2 }' $pkg/$pkg.cabal)
printf "'haskell-$pkg$2$version'\n "
done
# also add cabal
version=$(awk 'tolower($0) ~ /^version:/ { print $2 }' Cabal/Cabal/Cabal.cabal)
printf "'haskell-cabal$2$version'\n "
echo -e '\b)'
}
print_var 'provides' '='
print_var 'replaces' '<'