added community/innoextract

community/innoextract/PKGBUILD

@@ -0,0 +1,37 @@
+# Maintainer: Alad Wenter <alad@mailbox.org>
+# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
+# Contributor: Sam S. <smls75@gmail.com>
+# Contributor: Daniel Scharrer <daniel@constexpr.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - -DUSE_LTO=OFF
+
+pkgname=innoextract
+pkgver=1.8
+pkgrel=1
+pkgdesc="A tool to extract installers created by Inno Setup"
+url='https://constexpr.org/innoextract/'
+arch=('x86_64')
+license=('ZLIB')
+depends=('boost-libs' 'xz')
+makedepends=('boost' 'cmake')
+source=("https://constexpr.org/innoextract/files/$pkgname-$pkgver.tar.gz"
+        "https://constexpr.org/innoextract/files/$pkgname-$pkgver.tar.gz.sig")
+sha256sums=('5e78f6295119eeda08a54dcac75306a1a4a40d0cb812ff3cd405e9862c285269'
+            'SKIP')
+validpgpkeys=("ADE9653703D4ADE0E997758128555A66D7E1DEC9") # Daniel Scharrer <daniel@constexpr.org>
+
+build() {
+    cd "$pkgname-$pkgver"
+    cmake . -DCMAKE_INSTALL_PREFIX=/usr -DBoost_NO_BOOST_CMAKE=ON -DUSE_LTO=OFF
+    make
+}
+
+package() {
+    cd "$pkgname-$pkgver"
+    make DESTDIR="$pkgdir/" install
+
+    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
+    install -m644  CHANGELOG "$pkgdir/usr/share/doc/$pkgname/CHANGELOG"
+    install -Dm644 LICENSE   "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}