added extra/libwebp

extra/libwebp/PKGBUILD

@@ -0,0 +1,46 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Alexander Rødseth <rodseth@gmail.com>
+# Contributor: Jon Nordby <jononor@gmail.com>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - disable neon on !AArch64
+
+pkgname=libwebp
+pkgver=0.5.1
+pkgrel=1
+pkgdesc="WebP library and conversion tools"
+arch=(x86_64 i686)
+url="https://developers.google.com/speed/webp/"
+license=(BSD)
+depends=(libpng libjpeg libtiff giflib)
+makedepends=(freeglut mesa glu)
+optdepends=('freeglut: vwebp viewer')
+source=("http://downloads.webmproject.org/releases/webp/$pkgname-$pkgver.tar.gz")
+sha256sums=('6ad66c6fcd60a023de20b6856b03da8c7d347269d76b1fd9c3287e8b5e8813df')
+
+prepare() {
+  cd "$srcdir/$pkgname-$pkgver"
+}
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  [[ $CARCH != "aarch64" ]] && CONFIG="--disable-neon"
+
+  ./configure --prefix=/usr \
+     --enable-swap-16bit-csp \
+     --enable-experimental \
+     --enable-libwebp{mux,demux,decoder,extras} \
+     --disable-static $CONFIG
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir/" install
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}
+
+# vim:set ts=2 sw=2 et: