added extra/gnome-desktop

extra/gnome-desktop/PKGBUILD

@@ -0,0 +1,48 @@
+# $Id$
+# Maintainer:  Jan de Groot <jan@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - configure with --enable-compile-warnings=no
+
+pkgname=gnome-desktop
+pkgver=3.28.0
+pkgrel=1
+epoch=1
+pkgdesc="Library with common API for various GNOME modules"
+url="https://git.gnome.org/browse/gnome-desktop"
+arch=(x86_64)
+license=(GPL LGPL)
+depends=(gsettings-desktop-schemas gtk3 libxkbfile xkeyboard-config iso-codes libseccomp bubblewrap)
+makedepends=(intltool gobject-introspection git autoconf-archive gtk-doc yelp-tools)
+_commit=5e30118786eb767001fc8bfc8d130127b9538297  # tags/3.28.0^0
+source=("git+https://git.gnome.org/browse/gnome-desktop#commit=$_commit"
+        bwrap-var.diff)
+sha256sums=('SKIP'
+            '701bfa5779ced0f50241d4370068fc58246d47088c6e95be27d204847866f106')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  patch -Np1 -i ../bwrap-var.diff  # evince-thumbnailer needs fontconfig cache
+  intltoolize
+  gtkdocize
+  autoreconf -fvi
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib --disable-static --enable-gtk-doc \
+    --with-gnome-distributor="Arch Linux" --enable-compile-warnings=no
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}

extra/gnome-desktop/bwrap-var.diff

@@ -0,0 +1,15 @@
+ libgnome-desktop/gnome-desktop-thumbnail-script.c | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git c/libgnome-desktop/gnome-desktop-thumbnail-script.c i/libgnome-desktop/gnome-desktop-thumbnail-script.c
+index 99d83ac25d4cb449..7f85da2dec60f454 100644
+--- c/libgnome-desktop/gnome-desktop-thumbnail-script.c
++++ i/libgnome-desktop/gnome-desktop-thumbnail-script.c
+@@ -505,6 +505,7 @@ add_bwrap (GPtrArray   *array,
+ 
+   add_args (array,
+ 	    "bwrap",
++	    "--ro-bind", "/var", "/var",
+ 	    "--ro-bind", "/usr", "/usr",
+ 	    "--ro-bind", "/lib", "/lib",
+ 	    "--ro-bind", "/lib64", "/lib64",