added core/lzo

core/lzo/PKGBUILD

@@ -0,0 +1,50 @@
+# $Id$
+# Contributor: Low Kian Seong <fastmail_low@speedymail.org>
+# Maintainer: dorphell <dorphell@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - disable unaligned access on v5 with -DLZO_CFG_NO_UNALIGNED
+
+pkgname=lzo
+pkgver=2.08
+pkgrel=3.1
+pkgdesc="Portable lossless data compression library"
+arch=('i686' 'x86_64')
+url="http://www.oberhumer.com/opensource/lzo"
+license=('GPL')
+depends=('glibc')
+provides=("lzo2=$pkgver")
+replaces=('lzo2')
+conflicts=('lzo2')
+source=(http://www.oberhumer.com/opensource/lzo/download/lzo-${pkgver}.tar.gz)
+md5sums=('fcec64c26a0f4f4901468f360029678f')
+
+build() {
+  cd "${srcdir}/lzo-${pkgver}"
+
+  [[ $CARCH == "arm" ]] && CPPFLAGS+=" -DLZO_CFG_NO_UNALIGNED"
+
+  ./configure --prefix=/usr --enable-shared
+  make
+
+  # build minilzo
+  gcc $CFLAGS -fpic -Iinclude/lzo -o minilzo/minilzo.o -c minilzo/minilzo.c
+  gcc $LDFLAGS -shared -o libminilzo.so.0 -Wl,-soname,libminilzo.so.0 minilzo/minilzo.o
+}
+
+check() {
+  cd "${srcdir}/lzo-${pkgver}"
+  make test # Larger test
+  make check
+}
+
+package() {
+  cd "${srcdir}/lzo-${pkgver}"
+  make DESTDIR=${pkgdir} install
+
+  # install minilzo
+  install -m 755 libminilzo.so.0 ${pkgdir}/usr/lib
+  install -p -m 644 minilzo/minilzo.h ${pkgdir}/usr/include/lzo
+  cd ${pkgdir}/usr/lib
+  ln -s libminilzo.so.0 libminilzo.so
+}