diff --git a/extra/php/PKGBUILD b/extra/php/PKGBUILD
new file mode 100644
index 000000000..ab70837b4
--- /dev/null
+++ b/extra/php/PKGBUILD
@@ -0,0 +1,345 @@
+# Maintainer: Pierre Schmitz <pierre@archlinux.de>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - add -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64 to CPPFLAGS
+
+pkgbase=php
+pkgname=('php'
+         'php-cgi'
+         'php-apache'
+         'php-fpm'
+         'php-embed'
+         'php-phpdbg'
+         'php-dblib'
+         'php-enchant'
+         'php-gd'
+         'php-imap'
+         'php-intl'
+         'php-sodium'
+         'php-odbc'
+         'php-pgsql'
+         'php-pspell'
+         'php-snmp'
+         'php-sqlite'
+         'php-tidy'
+         'php-xsl')
+pkgver=7.4.9
+pkgrel=1.1
+arch=('x86_64')
+license=('PHP')
+url='https://www.php.net/'
+makedepends=('apache' 'aspell' 'c-client' 'db' 'enchant' 'gd' 'gmp' 'icu' 'libsodium' 'libxslt' 'libzip' 'net-snmp'
+             'postgresql-libs' 'sqlite' 'systemd' 'tidy' 'unixodbc' 'curl' 'libtool' 'postfix' 'freetds' 'pcre2' 'libnsl'
+             'oniguruma')
+checkdepends=('procps-ng')
+source=("https://php.net/distributions/${pkgbase}-${pkgver}.tar.xz"{,.asc}
+        'apache.patch' 'apache.conf' 'php-fpm.patch' 'php-fpm.tmpfiles' 'php.ini.patch'
+        'enchant-2.patch')
+sha512sums=('6179c2d867d6775d7f41785003c36d06ce620e7746ea7e6a4d275264e814a66d465776b47b04e2926ed1228cf58f2c15cdda74faf10372435c74ede7aeb79e18'
+            'SKIP'
+            '284e3c0fe3ded0ff3e7d53f2769ea207b4591ef42abeff2d8604e87fe379929bd3b19ff294a729834f339a9da85ae7d4a7d8605890677222f78601b4f2b22247'
+            'eccbe1a0c7b2757ab3c982c871cc591a66ad70f085aaa0d44f93cacacedc7b8fd21b8d0c66471327ff070db1bab1ab83a802f6fa190f33bdd74c134975e3910e'
+            '86ee6630bf0cac43bbf5a4b3918e63f32e01e74ac00845ebba2d122e14300bb47b41af17d88dfbf655b3a03966f5619b87b6f1ad8623e22482fe46be273309cb'
+            '824e9a0d10063283357d49a81ab49bf834afd24f098482bdbaa9ab60bbad2b0dea6f5879259b73717d437626b02fb4f2d3ef68b7bcbb26bee274a7b61144720f'
+            'a924bfece3d57286dce44f0173dd856184e7a1c1de5e880229c7dac0874efde52090af155932614f2594eebba118f8b89ac48e48d1161e7b3d8a95a93a24fe5d'
+            '5d7d44d692848fbb952e17e5bd6dffa79b764526e4940fbe0a5138ad62cb41abdb8c9bb8dd64cd1d0b488c74972bcf3f9c6d32a3bbeac90982fdf6321d3ec788')
+validpgpkeys=('5A52880781F755608BF815FC910DEB46F53EA312'
+              '42670A7FE4D0441C8E4632349E4FDC074A4EF02D')
+
+prepare() {
+	cd ${srcdir}/${pkgbase}-${pkgver}
+
+	patch -p0 -i ${srcdir}/apache.patch
+	patch -p0 -i ${srcdir}/php-fpm.patch
+	patch -p0 -i ${srcdir}/php.ini.patch
+	patch -p0 -i ${srcdir}/enchant-2.patch
+	autoconf
+
+	rm tests/output/stream_isatty_*.phpt
+}
+
+build() {
+	# http://site.icu-project.org/download/61#TOC-Migration-Issues
+	CPPFLAGS+=' -DU_USING_ICU_NAMESPACE=1 -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64'
+
+	local _phpconfig="--srcdir=../${pkgbase}-${pkgver} \
+		--config-cache \
+		--prefix=/usr \
+		--sbindir=/usr/bin \
+		--sysconfdir=/etc/php \
+		--localstatedir=/var \
+		--with-layout=GNU \
+		--with-config-file-path=/etc/php \
+		--with-config-file-scan-dir=/etc/php/conf.d \
+		--disable-rpath \
+		--mandir=/usr/share/man \
+		"
+
+	local _phpextensions="\
+		--enable-bcmath=shared \
+		--enable-calendar=shared \
+		--enable-dba=shared \
+		--enable-exif=shared \
+		--enable-ftp=shared \
+		--enable-gd=shared \
+		--enable-intl=shared \
+		--enable-mbstring \
+		--enable-pcntl \
+		--enable-shmop=shared \
+		--enable-soap=shared \
+		--enable-sockets=shared \
+		--enable-sysvmsg=shared \
+		--enable-sysvsem=shared \
+		--enable-sysvshm=shared \
+		--with-bz2=shared \
+		--with-curl=shared \
+		--with-db4=/usr \
+		--with-enchant=shared \
+		--with-external-gd \
+		--with-external-pcre \
+		--with-ffi=shared \
+		--with-gdbm \
+		--with-gettext=shared \
+		--with-gmp=shared \
+		--with-iconv=shared \
+		--with-imap-ssl \
+		--with-imap=shared \
+		--with-kerberos \
+		--with-ldap=shared \
+		--with-ldap-sasl \
+		--with-mhash \
+		--with-mysql-sock=/run/mysqld/mysqld.sock \
+		--with-mysqli=shared,mysqlnd \
+		--with-openssl \
+		--with-password-argon2 \
+		--with-pdo-dblib=shared,/usr \
+		--with-pdo-mysql=shared,mysqlnd \
+		--with-pdo-odbc=shared,unixODBC,/usr \
+		--with-pdo-pgsql=shared \
+		--with-pdo-sqlite=shared \
+		--with-pgsql=shared \
+		--with-pspell=shared \
+		--with-readline \
+		--with-snmp=shared \
+		--with-sodium=shared \
+		--with-sqlite3=shared \
+		--with-tidy=shared \
+		--with-unixODBC=shared \
+		--with-xmlrpc=shared \
+		--with-xsl=shared \
+		--with-zip=shared \
+		--with-zlib \
+		"
+
+	EXTENSION_DIR=/usr/lib/php/modules
+	export EXTENSION_DIR
+
+	mkdir ${srcdir}/build
+	cd ${srcdir}/build
+	ln -s ../${pkgbase}-${pkgver}/configure
+	./configure ${_phpconfig} \
+		--enable-cgi \
+		--enable-fpm \
+		--with-fpm-systemd \
+		--with-fpm-acl \
+		--with-fpm-user=http \
+		--with-fpm-group=http \
+		--enable-embed=shared \
+		${_phpextensions}
+	make
+
+	# apache
+	# reuse the previous run; this will save us a lot of time
+	cp -a ${srcdir}/build ${srcdir}/build-apache
+	cd ${srcdir}/build-apache
+	./configure ${_phpconfig} \
+		--with-apxs2 \
+		${_phpextensions}
+	make
+
+	# phpdbg
+	cp -a ${srcdir}/build ${srcdir}/build-phpdbg
+	cd ${srcdir}/build-phpdbg
+	./configure ${_phpconfig} \
+		--enable-phpdbg \
+		${_phpextensions}
+	make
+}
+
+check() {
+	cd ${srcdir}/build
+
+	# Check if sendmail was configured correctly (FS#47600)
+	sapi/cli/php -n -r 'echo ini_get("sendmail_path");' | grep -q '/usr/bin/sendmail'
+
+	export REPORT_EXIT_STATUS=1
+	export NO_INTERACTION=1
+	export SKIP_ONLINE_TESTS=1
+	export SKIP_SLOW_TESTS=1
+	export TEST_PHP_ARGS="-j$(nproc)"
+	export TESTS='tests Zend'
+
+	make test
+}
+
+package_php() {
+	pkgdesc='A general-purpose scripting language that is especially suited to web development'
+	depends=('libxml2' 'curl' 'libzip' 'pcre2' 'argon2' 'oniguruma')
+	replaces=('php-ldap')
+	conflicts=('php-ldap')
+	provides=("php-ldap=${pkgver}")
+	backup=('etc/php/php.ini')
+
+	cd ${srcdir}/build
+	make -j1 INSTALL_ROOT=${pkgdir} install-{modules,cli,build,headers,programs,pharcmd}
+	install -D -m644 ${srcdir}/${pkgbase}-${pkgver}/php.ini-production ${pkgdir}/etc/php/php.ini
+	install -d -m755 ${pkgdir}/etc/php/conf.d/
+
+	# remove static modules
+	rm -f ${pkgdir}/usr/lib/php/modules/*.a
+	# remove modules provided by sub packages
+	rm -f ${pkgdir}/usr/lib/php/modules/{enchant,gd,imap,intl,sodium,odbc,pdo_dblib,pdo_odbc,pgsql,pdo_pgsql,pspell,snmp,sqlite3,pdo_sqlite,tidy,xsl}.so
+	# remove empty directory
+	rmdir ${pkgdir}/usr/include/php/include
+}
+
+package_php-cgi() {
+	pkgdesc='CGI and FCGI SAPI for PHP'
+	depends=('php')
+
+	cd ${srcdir}/build
+	make -j1 INSTALL_ROOT=${pkgdir} install-cgi
+}
+
+package_php-apache() {
+	pkgdesc='Apache SAPI for PHP'
+	depends=('php' 'apache' 'libnsl')
+	backup=('etc/httpd/conf/extra/php7_module.conf')
+
+	install -D -m755 ${srcdir}/build-apache/libs/libphp7.so ${pkgdir}/usr/lib/httpd/modules/libphp7.so
+	install -D -m644 ${srcdir}/apache.conf ${pkgdir}/etc/httpd/conf/extra/php7_module.conf
+}
+
+package_php-fpm() {
+	pkgdesc='FastCGI Process Manager for PHP'
+	depends=('php' 'systemd')
+	backup=('etc/php/php-fpm.conf' 'etc/php/php-fpm.d/www.conf')
+	options=('!emptydirs')
+
+	cd ${srcdir}/build
+	make -j1 INSTALL_ROOT=${pkgdir} install-fpm
+	install -D -m644 sapi/fpm/php-fpm.service ${pkgdir}/usr/lib/systemd/system/php-fpm.service
+	install -D -m644 ${srcdir}/php-fpm.tmpfiles ${pkgdir}/usr/lib/tmpfiles.d/php-fpm.conf
+}
+
+package_php-embed() {
+	pkgdesc='Embedded PHP SAPI library'
+	depends=('php' 'systemd-libs' 'libnsl')
+	options=('!emptydirs')
+
+	cd ${srcdir}/build
+	make -j1 INSTALL_ROOT=${pkgdir} PHP_SAPI=embed install-sapi
+}
+
+package_php-phpdbg() {
+	pkgdesc='Interactive PHP debugger'
+	depends=('php')
+	options=('!emptydirs')
+
+	cd ${srcdir}/build-phpdbg
+	make -j1 INSTALL_ROOT=${pkgdir} install-phpdbg
+}
+
+package_php-dblib() {
+	pkgdesc='dblib module for PHP'
+	depends=('php' 'freetds')
+
+	install -D -m755 ${srcdir}/build/modules/pdo_dblib.so ${pkgdir}/usr/lib/php/modules/pdo_dblib.so
+}
+
+package_php-enchant() {
+	pkgdesc='enchant module for PHP'
+	depends=('php' 'enchant')
+
+	install -D -m755 ${srcdir}/build/modules/enchant.so ${pkgdir}/usr/lib/php/modules/enchant.so
+}
+
+package_php-gd() {
+	pkgdesc='gd module for PHP'
+	depends=('php' 'gd')
+
+	install -D -m755 ${srcdir}/build/modules/gd.so ${pkgdir}/usr/lib/php/modules/gd.so
+}
+
+package_php-imap() {
+	pkgdesc='imap module for PHP'
+	depends=('php' 'c-client')
+
+	install -D -m755 ${srcdir}/build/modules/imap.so ${pkgdir}/usr/lib/php/modules/imap.so
+}
+
+package_php-intl() {
+	pkgdesc='intl module for PHP'
+	depends=('php' 'icu')
+
+	install -D -m755 ${srcdir}/build/modules/intl.so ${pkgdir}/usr/lib/php/modules/intl.so
+}
+
+package_php-sodium() {
+	pkgdesc='sodium module for PHP'
+	depends=('php' 'libsodium')
+
+	install -D -m755 ${srcdir}/build/modules/sodium.so ${pkgdir}/usr/lib/php/modules/sodium.so
+}
+
+package_php-odbc() {
+	pkgdesc='ODBC modules for PHP'
+	depends=('php' 'unixodbc')
+
+	install -D -m755 ${srcdir}/build/modules/odbc.so ${pkgdir}/usr/lib/php/modules/odbc.so
+	install -D -m755 ${srcdir}/build/modules/pdo_odbc.so ${pkgdir}/usr/lib/php/modules/pdo_odbc.so
+}
+
+package_php-pgsql() {
+	pkgdesc='PostgreSQL modules for PHP'
+	depends=('php' 'postgresql-libs')
+
+	install -D -m755 ${srcdir}/build/modules/pgsql.so ${pkgdir}/usr/lib/php/modules/pgsql.so
+	install -D -m755 ${srcdir}/build/modules/pdo_pgsql.so ${pkgdir}/usr/lib/php/modules/pdo_pgsql.so
+}
+
+package_php-pspell() {
+	pkgdesc='pspell module for PHP'
+	depends=('php' 'aspell')
+
+	install -D -m755 ${srcdir}/build/modules/pspell.so ${pkgdir}/usr/lib/php/modules/pspell.so
+}
+
+package_php-snmp() {
+	pkgdesc='snmp module for PHP'
+	depends=('php' 'net-snmp')
+
+	install -D -m755 ${srcdir}/build/modules/snmp.so ${pkgdir}/usr/lib/php/modules/snmp.so
+}
+
+package_php-sqlite() {
+	pkgdesc='sqlite module for PHP'
+	depends=('php' 'sqlite')
+
+	install -D -m755 ${srcdir}/build/modules/sqlite3.so ${pkgdir}/usr/lib/php/modules/sqlite3.so
+	install -D -m755 ${srcdir}/build/modules/pdo_sqlite.so ${pkgdir}/usr/lib/php/modules/pdo_sqlite.so
+}
+
+package_php-tidy() {
+	pkgdesc='tidy module for PHP'
+	depends=('php' 'tidy')
+
+	install -D -m755 ${srcdir}/build/modules/tidy.so ${pkgdir}/usr/lib/php/modules/tidy.so
+}
+
+package_php-xsl() {
+	pkgdesc='xsl module for PHP'
+	depends=('php' 'libxslt')
+
+	install -D -m755 ${srcdir}/build/modules/xsl.so ${pkgdir}/usr/lib/php/modules/xsl.so
+}
diff --git a/extra/php/apache.conf b/extra/php/apache.conf
new file mode 100644
index 000000000..b516b5e66
--- /dev/null
+++ b/extra/php/apache.conf
@@ -0,0 +1,13 @@
+# Required modules: dir_module, php7_module
+
+<IfModule dir_module>
+	<IfModule php7_module>
+		DirectoryIndex index.php index.html
+		<FilesMatch "\.php$">
+			SetHandler application/x-httpd-php
+		</FilesMatch>
+		<FilesMatch "\.phps$">
+			SetHandler application/x-httpd-php-source
+		</FilesMatch>
+	</IfModule>
+</IfModule>
diff --git a/extra/php/apache.patch b/extra/php/apache.patch
new file mode 100644
index 000000000..c64021b8f
--- /dev/null
+++ b/extra/php/apache.patch
@@ -0,0 +1,10 @@
+--- sapi/apache2handler/config.m4.orig
++++ sapi/apache2handler/config.m4
+@@ -111,7 +111,6 @@
+       PHP_BUILD_THREAD_SAFE
+     fi
+   else
+-    APACHE_THREADED_MPM=`$APXS_HTTPD -V 2>/dev/null | grep 'threaded:.*yes'`
+     if test -n "$APACHE_THREADED_MPM"; then
+       PHP_BUILD_THREAD_SAFE
+     fi
diff --git a/extra/php/enchant-2.patch b/extra/php/enchant-2.patch
new file mode 100644
index 000000000..5aee2f729
--- /dev/null
+++ b/extra/php/enchant-2.patch
@@ -0,0 +1,49 @@
+--- ext/enchant/config.m4.orig
++++ ext/enchant/config.m4
+@@ -4,7 +4,7 @@
+     [Include Enchant support])])
+ 
+ if test "$PHP_ENCHANT" != "no"; then
+-  PKG_CHECK_MODULES([ENCHANT], [enchant])
++  PKG_CHECK_MODULES([ENCHANT], [enchant-2])
+ 
+   PHP_EVAL_INCLINE($ENCHANT_CFLAGS)
+   PHP_EVAL_LIBLINE($ENCHANT_LIBS, ENCHANT_SHARED_LIBADD)
+--- ext/enchant/enchant.c.orig
++++ ext/enchant/enchant.c
+@@ -738,7 +738,7 @@
+ 			for (i = 0; i < n_sugg; i++) {
+ 				add_next_index_string(sugg, suggs[i]);
+ 			}
+-			enchant_dict_free_suggestions(pdict->pdict, suggs);
++			enchant_dict_free_string_list(pdict->pdict, suggs);
+ 		}
+ 
+ 
+@@ -793,7 +793,7 @@
+ 			add_next_index_string(return_value, suggs[i]);
+ 		}
+ 
+-		enchant_dict_free_suggestions(pdict->pdict, suggs);
++		enchant_dict_free_string_list(pdict->pdict, suggs);
+ 	}
+ }
+ /* }}} */
+@@ -813,7 +813,7 @@
+ 
+ 	PHP_ENCHANT_GET_DICT;
+ 
+-	enchant_dict_add_to_personal(pdict->pdict, word, wordlen);
++	enchant_dict_add(pdict->pdict, word, wordlen);
+ }
+ /* }}} */
+ 
+@@ -851,7 +851,7 @@
+ 
+ 	PHP_ENCHANT_GET_DICT;
+ 
+-	RETURN_BOOL(enchant_dict_is_in_session(pdict->pdict, word, wordlen));
++	RETURN_BOOL(enchant_dict_is_added(pdict->pdict, word, wordlen));
+ }
+ /* }}} */
+ 
diff --git a/extra/php/generate_patches b/extra/php/generate_patches
new file mode 100755
index 000000000..b417124a0
--- /dev/null
+++ b/extra/php/generate_patches
@@ -0,0 +1,63 @@
+#!/bin/bash
+
+. PKGBUILD
+
+makepkg -o --nodeps --noprepare --skipinteg
+
+pushd src/${pkgbase}-${pkgver}
+
+sed '/APACHE_THREADED_MPM=/d' -i.orig sapi/apache2handler/config.m4
+
+sed 's/.conf.default/.conf/g' -i.orig sapi/fpm/Makefile.frag
+
+sed \
+	-e 's#run/php-fpm.pid#/run/php-fpm/php-fpm.pid#' \
+	-e 's#^;error_log =.*#error_log = syslog#' \
+	-i.orig sapi/fpm/php-fpm.conf.in
+
+sed \
+	-e 's#^listen =.*#listen = /run/php-fpm/php-fpm.sock#' \
+	-e 's#^;listen.owner =#listen.owner =#' \
+	-e 's#^;listen.group =#listen.group =#' \
+	-e 's#^;chdir =.*#;chdir = /srv/http#' \
+	-i.orig sapi/fpm/www.conf.in
+
+sed \
+	-e 's#^PIDFile=.*#PIDFile=/run/php-fpm/php-fpm.pid#' \
+	-i.orig sapi/fpm/php-fpm.service.in
+
+extensions=";extension=bcmath\n;extension=bz2\n;extension=calendar\nextension=curl\n;extension=dba\n;extension=enchant\n;extension=exif\n;extension=ffi\n;extension=ftp\n;extension=gd\n;extension=gettext\n;extension=gmp\n;extension=iconv\n;extension=imap\n;extension=intl\n;extension=ldap\n;extension=mysqli\n;extension=odbc\n;zend_extension=opcache\n;extension=pdo_dblib\n;extension=pdo_mysql\n;extension=pdo_odbc\n;extension=pdo_pgsql\n;extension=pdo_sqlite\n;extension=pgsql\n;extension=pspell\n;extension=shmop\n;extension=snmp\n;extension=soap\n;extension=sockets\n;extension=sodium\n;extension=sqlite3\n;extension=sysvmsg\n;extension=sysvsem\n;extension=sysvshm\n;extension=tidy\n;extension=xmlrpc\n;extension=xsl\nextension=zip\n"
+
+sed \
+	-r ":a;N;\$!ba;s/; Notes for Windows environments :\n.+;?extension=\w+\n/${extensions}/g" \
+	-i.orig php.ini-production
+sed \
+	-e 's#^;extension_dir = "\./"$#extension_dir = "/usr/lib/php/modules/"#g' \
+	-i php.ini-production
+
+sed \
+	-r 's#PKG_CHECK_MODULES\(\[ENCHANT\], \[enchant\]\)#PKG_CHECK_MODULES([ENCHANT], [enchant-2])#g' \
+	-i.orig ext/enchant/config.m4
+sed \
+	-r 's#enchant_dict_free_suggestions\(pdict->pdict, suggs\)#enchant_dict_free_string_list(pdict->pdict, suggs)#g' \
+	-i.orig ext/enchant/enchant.c
+sed \
+	-r 's#enchant_dict_add_to_personal\(pdict->pdict, word, wordlen\)#enchant_dict_add(pdict->pdict, word, wordlen)#g' \
+	-i ext/enchant/enchant.c
+sed \
+	-r 's#enchant_dict_is_in_session\(pdict->pdict, word, wordlen\)#enchant_dict_is_added(pdict->pdict, word, wordlen)#g' \
+	-i ext/enchant/enchant.c
+
+diff -u sapi/apache2handler/config.m4.orig sapi/apache2handler/config.m4 | filterdiff --clean --remove-timestamps > ../../apache.patch
+
+diff -u sapi/fpm/Makefile.frag.orig sapi/fpm/Makefile.frag | filterdiff --clean --remove-timestamps > ../../php-fpm.patch
+diff -u sapi/fpm/php-fpm.conf.in.orig sapi/fpm/php-fpm.conf.in | filterdiff --clean --remove-timestamps >> ../../php-fpm.patch
+diff -u sapi/fpm/www.conf.in.orig sapi/fpm/www.conf.in | filterdiff --clean --remove-timestamps >> ../../php-fpm.patch
+diff -u sapi/fpm/php-fpm.service.in.orig sapi/fpm/php-fpm.service.in | filterdiff --clean --remove-timestamps >> ../../php-fpm.patch
+
+diff -u php.ini-production.orig php.ini-production | filterdiff --clean --remove-timestamps > ../../php.ini.patch
+
+diff -u ext/enchant/config.m4.orig ext/enchant/config.m4 | filterdiff --clean --remove-timestamps > ../../enchant-2.patch
+diff -u ext/enchant/enchant.c.orig ext/enchant/enchant.c | filterdiff --clean --remove-timestamps >> ../../enchant-2.patch
+
+popd
diff --git a/extra/php/php-fpm.patch b/extra/php/php-fpm.patch
new file mode 100644
index 000000000..c74134220
--- /dev/null
+++ b/extra/php/php-fpm.patch
@@ -0,0 +1,74 @@
+--- sapi/fpm/Makefile.frag.orig
++++ sapi/fpm/Makefile.frag
+@@ -15,8 +15,8 @@
+ 	else \
+ 		echo "Installing PHP FPM defconfig:     $(INSTALL_ROOT)$(sysconfdir)/" && \
+ 		$(mkinstalldirs) $(INSTALL_ROOT)$(sysconfdir)/php-fpm.d; \
+-		$(INSTALL_DATA) sapi/fpm/php-fpm.conf $(INSTALL_ROOT)$(sysconfdir)/php-fpm.conf.default; \
+-		$(INSTALL_DATA) sapi/fpm/www.conf $(INSTALL_ROOT)$(sysconfdir)/php-fpm.d/www.conf.default; \
++		$(INSTALL_DATA) sapi/fpm/php-fpm.conf $(INSTALL_ROOT)$(sysconfdir)/php-fpm.conf; \
++		$(INSTALL_DATA) sapi/fpm/www.conf $(INSTALL_ROOT)$(sysconfdir)/php-fpm.d/www.conf; \
+ 	fi
+ 
+ 	@echo "Installing PHP FPM man page:      $(INSTALL_ROOT)$(mandir)/man8/"
+--- sapi/fpm/php-fpm.conf.in.orig
++++ sapi/fpm/php-fpm.conf.in
+@@ -14,14 +14,14 @@
+ ; Pid file
+ ; Note: the default prefix is @EXPANDED_LOCALSTATEDIR@
+ ; Default Value: none
+-;pid = run/php-fpm.pid
++;pid = /run/php-fpm/php-fpm.pid
+ 
+ ; Error log file
+ ; If it's set to "syslog", log is sent to syslogd instead of being written
+ ; into a local file.
+ ; Note: the default prefix is @EXPANDED_LOCALSTATEDIR@
+ ; Default Value: log/php-fpm.log
+-;error_log = log/php-fpm.log
++error_log = syslog
+ 
+ ; syslog_facility is used to specify what type of program is logging the
+ ; message. This lets syslogd specify that messages from different facilities
+--- sapi/fpm/www.conf.in.orig
++++ sapi/fpm/www.conf.in
+@@ -33,7 +33,7 @@
+ ;                            (IPv6 and IPv4-mapped) on a specific port;
+ ;   '/path/to/unix/socket' - to listen on a unix socket.
+ ; Note: This value is mandatory.
+-listen = 127.0.0.1:9000
++listen = /run/php-fpm/php-fpm.sock
+ 
+ ; Set listen(2) backlog.
+ ; Default Value: 511 (-1 on FreeBSD and OpenBSD)
+@@ -45,8 +45,8 @@
+ ; and group can be specified either by name or by their numeric IDs.
+ ; Default Values: user and group are set as the running user
+ ;                 mode is set to 0660
+-;listen.owner = @php_fpm_user@
+-;listen.group = @php_fpm_group@
++listen.owner = @php_fpm_user@
++listen.group = @php_fpm_group@
+ ;listen.mode = 0660
+ ; When POSIX Access Control Lists are supported you can set them using
+ ; these options, value is a comma separated list of user/group names.
+@@ -371,7 +371,7 @@
+ ; Chdir to this directory at the start.
+ ; Note: relative path can be used.
+ ; Default Value: current directory or / when chroot
+-;chdir = /var/www
++;chdir = /srv/http
+ 
+ ; Redirect worker stdout and stderr into main error log. If not set, stdout and
+ ; stderr will be redirected to /dev/null according to FastCGI specs.
+--- sapi/fpm/php-fpm.service.in.orig
++++ sapi/fpm/php-fpm.service.in
+@@ -8,7 +8,7 @@
+ 
+ [Service]
+ Type=@php_fpm_systemd@
+-PIDFile=@EXPANDED_LOCALSTATEDIR@/run/php-fpm.pid
++PIDFile=/run/php-fpm/php-fpm.pid
+ ExecStart=@EXPANDED_SBINDIR@/php-fpm --nodaemonize --fpm-config @EXPANDED_SYSCONFDIR@/php-fpm.conf
+ ExecReload=/bin/kill -USR2 $MAINPID
+ 
diff --git a/extra/php/php-fpm.tmpfiles b/extra/php/php-fpm.tmpfiles
new file mode 100644
index 000000000..801e74f1e
--- /dev/null
+++ b/extra/php/php-fpm.tmpfiles
@@ -0,0 +1 @@
+d /run/php-fpm 755 root root
diff --git a/extra/php/php.ini.patch b/extra/php/php.ini.patch
new file mode 100644
index 000000000..22b5abb16
--- /dev/null
+++ b/extra/php/php.ini.patch
@@ -0,0 +1,77 @@
+--- php.ini-production.orig
++++ php.ini-production
+@@ -756,7 +756,7 @@
+ 
+ ; Directory in which the loadable extensions (modules) reside.
+ ; http://php.net/extension-dir
+-;extension_dir = "./"
++extension_dir = "/usr/lib/php/modules/"
+ ; On windows:
+ ;extension_dir = "ext"
+ 
+@@ -904,49 +904,45 @@
+ ; deprecated in a future PHP major version. So, when it is possible, please
+ ; move to the new ('extension=<ext>) syntax.
+ ;
+-; Notes for Windows environments :
+-;
+-; - Many DLL files are located in the extensions/ (PHP 4) or ext/ (PHP 5+)
+-;   extension folders as well as the separate PECL DLL download (PHP 5+).
+-;   Be sure to appropriately set the extension_dir directive.
+-;
++;extension=bcmath
+ ;extension=bz2
+-;extension=curl
++;extension=calendar
++extension=curl
++;extension=dba
++;extension=enchant
++;extension=exif
+ ;extension=ffi
+ ;extension=ftp
+-;extension=fileinfo
+-;extension=gd2
++;extension=gd
+ ;extension=gettext
+ ;extension=gmp
+-;extension=intl
++;extension=iconv
+ ;extension=imap
++;extension=intl
+ ;extension=ldap
+-;extension=mbstring
+-;extension=exif      ; Must be after mbstring as it depends on it
+ ;extension=mysqli
+-;extension=oci8_12c  ; Use with Oracle Database 12c Instant Client
+ ;extension=odbc
+-;extension=openssl
+-;extension=pdo_firebird
++;zend_extension=opcache
++;extension=pdo_dblib
+ ;extension=pdo_mysql
+-;extension=pdo_oci
+ ;extension=pdo_odbc
+ ;extension=pdo_pgsql
+ ;extension=pdo_sqlite
+ ;extension=pgsql
++;extension=pspell
+ ;extension=shmop
+-
+-; The MIBS data available in the PHP distribution must be installed.
+-; See http://www.php.net/manual/en/snmp.installation.php
+ ;extension=snmp
+-
+ ;extension=soap
+ ;extension=sockets
+ ;extension=sodium
+ ;extension=sqlite3
++;extension=sysvmsg
++;extension=sysvsem
++;extension=sysvshm
+ ;extension=tidy
+ ;extension=xmlrpc
+ ;extension=xsl
++extension=zip
+ 
+ ;;;;;;;;;;;;;;;;;;;
+ ; Module Settings ;