# $Id: PKGBUILD 82 2009-07-17 19:56:55Z aaron $
# Maintainer: Mateusz Herych <heniekk@gmail.com>

pkgname=lastfm-client
pkgver=1.5.1.31879
pkgrel=3
pkgdesc="The Last.fm client"
arch=('i686' 'x86_64')
url="http://www.last.fm/tools/downloads/"
license=('GPL')
depends=('libpng' 'libjpeg' 'libxinerama' 'libxi' 'fontconfig' 'alsa-lib' 'libxcursor' 'libsm' 'libxrandr' 'qt' 'fftw' 'libgpod' 'libsamplerate' 'libmad')
source=(http://cdn.last.fm/client/src/last.fm-$pkgver.tar.bz2
	lastfm.desktop
	gcc-4.3.patch
	build-fixes.diff
	set-firstrun-status.diff
	set-locale.diff
	makefile-qt45.patch)
md5sums=('21358960da6a68337c8afad79d268b5b'
         '9c5e444704d49cff7b1dc916f290bad0'
         'ea16fb44f5b8859f8d351b04f83ae34c'
         'ae0e4a94af0d9e38172f064642a32e20'
         '494d7c336b09c7d579dad3cc7d7bc627'
         '1aeec4db77dc7cbc8e4660f127485599'
         'bea1168abcacef30832bb1e88a25b5f3')

build() {
   cd $startdir/src/last.fm-$pkgver
   patch -Np1 -i ../build-fixes.diff || return 1
   patch -Np1 -i ../gcc-4.3.patch || return 1
   patch -Np1 -i ../set-locale.diff | return 1
   patch -Np1 -i ../set-firstrun-status.diff || return 1
   ./configure
   MAKEFLAGS=-j1 make src/Makefile || return 1
   patch -Np1 -i ../makefile-qt45.patch || return 1
   MAKEFLAGS=-j1 make || return 1
   (   make || (mv build/fplib/libfplib_debug.a build/fplib/libfplib.a && make ) ) || return 1
   mkdir -p $startdir/pkg/opt $startdir/pkg/usr/bin
   cp -rp  bin/ $startdir/pkg/opt/last.fm
   printf "#!/bin/sh\nexec /opt/last.fm/last.fm.sh\n" > $startdir/pkg/usr/bin/lastfm
   chmod +x $startdir/pkg/usr/bin/lastfm
   install -D -m 644 $startdir/src/lastfm.desktop $startdir/pkg/usr/share/applications/lastfm.desktop
}