# $Id: PKGBUILD 82 2009-07-17 19:56:55Z aaron $
# Maintainer: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: Alessio 'mOLOk' Bolognino <themolok@gmail.com>   

pkgname=mldonkey
pkgver=3.0.0
pkgrel=3
pkgdesc="A multi-network P2P client"
arch=('i686' 'x86_64')
url="http://mldonkey.sourceforge.net/"
license=('GPL')
depends=('desktop-file-utils' 'file' 'gd')
makedepends=('lablgtk2' 'librsvg' 'ocaml')
optdepends=('librsvg: GUI support'
            'libx11: GUI support')
backup=('etc/conf.d/mldonkey' 'etc/mldonkey.conf')
install=mldonkey.install
source=(http://downloads.sourceforge.net/sourceforge/mldonkey/${pkgname}-${pkgver}.tar.bz2
        mldonkeyd mldonkey.conf mldonkey.desktop)
md5sums=('d45b37f334a4008ed15343dfb2caf453' '55f4ee3a1d4a4c4c447c8815e3055cb5'
         '190cbbc30b510981e0d8b0ed8bae87a4' '1de3266caa49f82bee73ba891eea12cf')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  ./configure --prefix=/usr --enable-gui=newgui2
  make || return 1
  make DESTDIR=${pkgdir} install

  install -Dm644 ${srcdir}/${pkgname}-${pkgver}/icons/rsvg/type_source_normal.svg \
    ${pkgdir}/usr/share/icons/mldonkey.svg
  install -Dm644 ${srcdir}/mldonkey.desktop ${pkgdir}/usr/share/applications/mldonkey.desktop

  install -Dm755 ${srcdir}/mldonkeyd ${pkgdir}/etc/rc.d/mldonkey
  install -Dm644 ${srcdir}/mldonkey.conf ${pkgdir}/etc/conf.d/mldonkey
}

# vim:set ts=2 sw=2 et: