# $Id: PKGBUILD 2129 2009-09-09 00:03:20Z cprimier $
# Maintainer: Corrado 'bardo' Primier <corrado.primier@mail.polimi.it>
# Contributor: Jochem Kossen <j.kossen@home.nl>

pkgname=scite
pkgver=2.01
pkgrel=1
pkgdesc="A generally useful editor with facilities for building and running programs"
arch=('i686' 'x86_64')
url="http://www.scintilla.org/SciTE.html"
license=('custom:scite')
depends=('desktop-file-utils' 'gtk2')
install=${pkgname}.install
source=(http://downloads.sourceforge.net/sourceforge/scintilla/${pkgname}${pkgver/\./}.tgz
        SciTE.desktop makefile.patch)
md5sums=('ef4b6b4d903c29e4ab511488a0d20f46' '48526532ef677982a4b156ae90f25b6f'
         '8417a7310318423d34b6c3ae0090230e')

build() {
  cd ${srcdir}
  patch -Np0 -i ${srcdir}/makefile.patch || return 1

  cd ${srcdir}/scintilla/gtk
  sed -i "s/#ARCHCXXFLAGS#/${CXXFLAGS}/g" makefile
  make || return 1
  install -Dm644 ../License.txt ${pkgdir}/usr/share/licenses/scintilla/LICENSE

  cd ${srcdir}/${pkgname}/gtk
  sed -i "s/#ARCHCXXFLAGS#/${CXXFLAGS}/g" makefile
  make || return 1
  make DESTDIR=${pkgdir} install

  install -Dm644 ../License.txt ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
  install -Dm644 ${srcdir}/SciTE.desktop ${pkgdir}/usr/share/applications/
  ln -sf SciTE ${pkgdir}/usr/bin/scite
}

# vim:set ts=2 sw=2 et: