# $Id$
# Maintainer: David Runge <dave@sleepmap.de>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: SpepS <dreamspepser at yahoo dot it>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: DonVla <donvla@users.sourceforge.net>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - don't build with neon (-DNoNeonPlease=1)

pkgname=zynaddsubfx
pkgver=3.0.3
pkgrel=3
pkgdesc="Opensource software synthesizer capable of making a countless number of instruments."
arch=('x86_64')
url="http://zynaddsubfx.sourceforge.net"
license=('GPL2')
depends=('fftw' 'hicolor-icon-theme' 'lash' 'liblo' 'libxpm' 'mxml' 'ntk' 'portaudio')
makedepends=('asciidoc' 'cmake' 'doxygen' 'gnuplot' 'dblatex' 'imagemagick' 'ghostscript' 'texlive-pstricks')
source=("https://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.bz2")
sha512sums=('e60e22656388d444114959859c12014ec79d7ba555b0d217ad98ad06e273916eea0eee521bb9dbfdef5be34205280d355b44a8f15760eeff06b16410d560b5d7')

prepare() {
  cd "${pkgname}-${pkgver}"
  mkdir -vp build
}

build() {
  cd "${pkgname}-${pkgver}/build"

  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DDefaultOutput=jack \
    -DDefaultInput=jack \
    -DGuiModule=ntk \
    -DNoNeonPlease=1 \
    ..
  make
  # build documentation
  cd ../doc
  make
}

package() {
  cd "${pkgname}-${pkgver}/build"
  make DESTDIR="${pkgdir}/" install
  # banks and examples
  install -vd "${pkgdir}/usr/share/${pkgname}"
  cp -va ../instruments/banks "${pkgdir}/usr/share/${pkgname}"
  cp -va ../instruments/examples "${pkgdir}/usr/share/${pkgname}"
  # icons
  install -vDm 644 "../${pkgname}.ico" \
    "${pkgdir}/usr/share/pixmaps/${pkgname}.ico"
  install -vDm 644 "../${pkgname}.svg" \
    "${pkgdir}/usr/share/icons/hicolor/scalable/apps/${pkgname}.svg"
  # man page
  install -vDm 644 "../doc/${pkgname}.1" \
    "${pkgdir}/usr/share/man/man1/${pkgname}.1"
  # documentation
  install -vDm 644 "../doc/${pkgname}.html" \
    "${pkgdir}/usr/share/doc/${pkgname}/${pkgname}.html"
  install -vDm 644 "../doc/${pkgname}.pdf" \
    "${pkgdir}/usr/share/doc/${pkgname}/${pkgname}.pdf"
  cp -va ../doc/images "${pkgdir}/usr/share/doc/${pkgname}/"
}