# Maintainer: Amr Hassan <amr.hassan@gmail.com>
# Maintainer: Nathan Owe <ndowens.aur at gmail dot com>
pkgname=flexget
_pkgname=FlexGet
pkgver=1.1.83
pkgrel=1
pkgdesc="Automate downloading or processing content (torrents, podcasts, etc.)"
arch=(any)
url="http://flexget.com/"
license=('MIT')
depends=('python2'
         # documented in FlexGet.egg-info/requires.txt
         'python2-beautifulsoup3>=3.2'
         'python2-beautifulsoup4>=4.2.1'
         'python2-cherrypy'
         'python2-dateutil>2.0'
         'python2-feedparser>=5.1.3'
         'python2-flask'
         'python2-html5lib>=0.11'
         'python2-jinja'
         'python2-jsonschema>=2.0' #AUR#
         'python2-progressbar'
         'python2-pynzb' #AUR#
         'python2-pyrss2gen' #AUR#
         'python2-requests>=1.0'
         'python2-sqlalchemy-0.7.9' #AUR# # support current 0.8.x someday? FIXME
         'python2-tvrage' #AUR#
         'python2-yaml'
         # undocumented in FlexGet.egg-info/requires.txt
         'python2-certifi>=0.0.7' #AUR# # possibly required by python2-requests
        #'python2-chardet>=1.0.0' # reason? imdb_lookup.py says installing it might help...
         )
optdepends=('python2-guppy: for memusage plugin' #AUR#
            'python2-transmissionrpc: Transmission support' #AUR#
            )
makedepends=('python2-distribute')
source=("http://download.flexget.com/${_pkgname}-${pkgver}.tar.gz")
md5sums=('2c90f9207f46b8fc9d1ed21befd441ed')

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python2 setup.py install --root="${pkgdir}/" optimize=1
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}