# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Ronald van Haren <ronald.archlinux.org>

pkgname=e-modules-extra-svn
pkgver=42797
pkgrel=1
pkgdesc="Extra gadgets for e17"
arch=('i686' 'x86_64')
groups=('e17-extra-svn')
url="http://www.enlightenment.org"
license=('BSD')
depends=('e-svn' 'exml-svn' 'libxkbfile' 'emprint-svn' 'libmpd' 'hal' 'efreet-svn' 'e_dbus-svn')
makedepends=('svn' 'cvs')
conflicts=('e-modules-extra')
provides=('e-modules-extra')
replaces=('e_modules-cvs')
options=('!libtool')
source=()
md5sums=()

_svntrunk="http://svn.enlightenment.org/svn/e/trunk/E-MODULES-EXTRA"
_svnmod="E-MODULES-EXTRA"

build() {
   cd $srcdir

  msg "Connecting to $_svntrunk SVN server...."
  if [ -d $_svnmod/.svn ]; then
    (cd $_svnmod && svn up -r $pkgver)
  else
    svn co $_svntrunk --config-dir ./ -r $pkgver $_svnmod
  fi

  msg "SVN checkout done or server timeout"
  msg "Starting make..."

  cp -r $_svnmod $_svnmod-build
  cd $_svnmod-build

# this compiles all extra e17 modules that DO compile atm
# if a new module does not appear here for several [community] releases
# in a row, please file a bug (I may have missed it in that case)


# TODO: split package
# do not use the debian directory
# drawer fails
for i in alarm bling calendar cpu deskshow diskio efm_path efm_pathbar efm_nav\
	emu execwatch flame forecasts language mail mem iiirk\
	moon mpdule net news penguins photo places rain screenshot slideshow \
	snow taskbar tclock tiling uptime weather winselector wlan; do

  cd $i
  ./autogen.sh --prefix=/usr
  make || return 1
  make DESTDIR=$pkgdir install || return 1

# install license files
  install -Dm644 $srcdir/$_svnmod-build/$i/COPYING \
  	$pkgdir/usr/share/licenses/$pkgname/$i/COPYING
  	
  install -Dm644 $srcdir/$_svnmod-build/$i/COPYING-PLAIN \
  	$pkgdir/usr/share/licenses/$pkgname/$i/COPYING-PLAIN

  cd ..
done
 
 rm -r $srcdir/$_svnmod-build
}