# $Id: PKGBUILD 925 2009-08-09 02:14:32Z ebelanger $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: Jo Christian Bergskås <jcberg@gmail.com>

pkgbase=fceux
pkgname=('fceux' 'gfceux')
pkgver=2.1.1
pkgrel=1
arch=('i686' 'x86_64')
url="http://fceux.com/web/htdocs/index.php"
license=('GPL')
depends=('sdl' 'zlib' 'zenity' 'lua' 'mesa')
makedepends=('scons')
source=(http://downloads.sourceforge.net/fceultra/fceux-${pkgver}.src.tar.bz2)
md5sums=('d669309a3fb15c002fffb24a801c2a9b')
sha1sums=('1846544b6cd67749708cc10cce86784b3107166a')

build() {
  cd "${srcdir}/fceu"
  scons || return 1
}

package_fceux() {
  pkgdesc="A fast and ultra-compatible NES/Famicom emulator with SDL, OpenGL and SVGALIB support"
  optdepends=('xchm: for viewing the help manual')
  provides=('fceu')
  replaces=('fceu')

  cd "${srcdir}/fceu"
  sed -i "s|/usr/local|${pkgdir}/usr|" SConstruct || return 1
  scons install || return 1
  install -D -m644 bin/fceux.chm "${pkgdir}/usr/share/doc/fceux/fceux.chm" || return 1
}

package_gfceux() {
  pkgdesc="A GUI for the popular Nintendo Emulator, FCEUX"
  depends=('pygtk' 'fceux')
  provides=('gfceu')
  replaces=('gfceu')

  cd "${srcdir}/gfceux"
  python setup.py install --root="${pkgdir}" || return 1
}