# $Id: PKGBUILD 2486 2009-09-19 11:38:30Z ibiru $
# Maintainer: dibblethewrecker dibblethewrecker.at.jiwe.dot.org

pkgname=grass
pkgver=6.4.0RC4
pkgrel=3
pkgdesc="Geographic Information System (GIS) used for geospatial data management and analysis, \
	image processing, graphics/maps production, spatial modeling, and visualization"
arch=('i686' 'x86_64')
url="http://grass.itc.it/index.php"
license=('GPL')
depends=('gdal' 'tk' 'sqlite3' 'xorg-server' 'python' 'mesa' 'swig' 'proj' 'libjpeg>=7' 'libpng' 'libtiff')
makedepends=('mysql' 'postgresql>=8.4.1' 'r' 'fftw' 'freetype2')
optdepends=('fftw: required for i.fft and i.ifft modules'
'postgresql: PostgreSQL database interface'
'r: R language interface'
'lapack: required for GMATH library'
'blas: required for GMATH library')
options=('!libtool' '!makeflags')
install=grass.install
source=(http://grass.itc.it/grass64/source/$pkgname-$pkgver.tar.gz $pkgname.desktop grass.sh grass.png)
md5sums=('ad830f3a6ff4ec162d29cde936c30a70' '7c68b6354ba3cf471250acb93570ff9a'\
         'db93730dd330f1539bd31b4373e1c00e' 'ae778ed261a40b078a8465994a0eb25e')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/opt --with-mysql-includes=/usr/include/mysql \
    --with-mysql --with-fftw --with-gdal=/usr/bin/gdal-config --with-sqlite --with-python --with-blas --with-lapack --with-postgres \
    --with-proj-libs=/usr/lib --with-proj-includes=/usr/include \
    --with-proj-share=/usr/share/proj \
    --with-fftw-includes=/usr/include --with-fftw-libs=/usr/lib || return 1
    #--with-freetype-includes=/usr/include
  
  make || return 1
  make INST_DIR=$pkgdir/opt/grass-$pkgver BINDIR=$pkgdir/usr/bin         install || return 1

  # fix $GISBASE path
  sed -i "s|GISBASE=$pkgdir/opt/grass-$pkgver|GISBASE=/opt/grass-$pkgver|g" "$pkgdir/usr/bin/grass64" || return 1

  # strip html docs
  rm -r "$pkgdir/opt/grass-$pkgver/docs/html"

  # install profile.d file
  install -D -m755 "$srcdir/grass.sh" "$pkgdir/etc/profile.d/grass.sh" || return 1
  
  # install some freedesktop.org compatibility
  install -D -m644 "$srcdir/$pkgname.desktop" \
      "$pkgdir/usr/share/applications/$pkgname.desktop" || return 1

  install -D -m644 "$srcdir/$pkgname.png" \
        "$pkgdir/usr/share/pixmaps/$pkgname.png" || return 1

  # create a symlink for version work around
  ln -sf /opt/grass-$pkgver "$pkgdir/opt/grass"
}
# vim:syntax=sh