# $Id: PKGBUILD 82 2009-07-17 19:56:55Z aaron $
# Contributor: Seppo Porspakka <sporspak@paju.oulu.fi>
 
pkgname=scorched3d
pkgver=42.1
pkgrel=2
pkgdesc="A 3d artillery combat game"
arch=('i686' 'x86_64')
url="http://www.scorched3d.co.uk/"
license=('GPL')
depends=('sdl_net' 'wxgtk' 'freealut>=1.0.0-3' 'libvorbis' 'mesa' 'fftw' 'libjpeg>=7')
makedepends=('sharutils')
source=(http://downloads.sourceforge.net/$pkgname/Scorched3D-$pkgver-src.tar.gz 	'scorched3d.desktop'
	'scorched3d.png.uu'
	'scorched3d-42.1-gcc43.patch'
	'scorched3d-42.1-fixups.patch')
md5sums=('e24867615568ef541a291a4813fcbdae'
         'b951f2150004e10fdff3e6226f1a3939'
         '178a281333006c6a5a92919865c1d7af'
         '053769f77a38c252eef1d967b18e93e6'
         'dfde556559d95bca07c4a390c60790b4')
 
build() {
  cd "$srcdir/scorched"
  patch -Np1 -i "$srcdir/scorched3d-42.1-gcc43.patch"
  patch -Np1 -i "$srcdir/scorched3d-42.1-fixups.patch"
  WANT_WXGTK=gtk2
  sh autogen.sh --prefix=/usr --datadir=/usr/share/scorched3d --disable-openaltest --with-wx-config=wx-config
  #sed -i 's/-lz/-lz -lalut/g' src/scorched/Makefile || return 1
  #sed -i 's|/usr/local/lib/libwx_gtk-2.4.a||' src/scorched/Makefile || return 1
  make || return 1
  make DESTDIR="$pkgdir" install
 
  # freedesktop stuff - png and desktop file ganked from debian
  cd "$srcdir"
  uudecode --output-file=scorched3d.png scorched3d.png.uu
  install -D -m644 scorched3d.png \
    "$pkgdir/usr/share/icons/hicolor/48x48/apps/$pkgname.png"
  install -D -m644 scorched3d.desktop \
    "$pkgdir/usr/share/applications/$pkgname.desktop"
}