# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: kfgz <kfgz@interia.pl>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch to attempt fixing ARM hackery by bandwagoning developers
#  - don't build 12- and 10-bit variants

pkgname=x265
pkgver=3.6
pkgrel=1
pkgdesc='Open Source H265/HEVC video encoder'
arch=(x86_64)
url=https://bitbucket.org/multicoreware/x265_git
license=(GPL)
depends=(gcc-libs)
makedepends=(
  cmake
  git
  nasm
  ninja
)
provides=(libx265.so)
_tag=aa7f602f7592eddb9d87749be7466da005b556ee
source=(git+https://bitbucket.org/multicoreware/x265_git#tag=${_tag}
        0001-arm-fixes.patch)
sha256sums=('31887d9871b7916dabe8bc4c71a5daf23ae109cdc677efaa258d2d19086cb67b'
            '9a527deb44ed5be459519d1e6721020bcbcbe74e73896b59e6df3a62888f152c')

pkgver() {
  cd x265_git

  git describe --tags
}

prepare() {
  cd x265_git
  git apply ../0001-arm-fixes.patch
}

build() {
  cmake -S x265_git/source -B build -G Ninja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DENABLE_SHARED=TRUE
  ninja -C build
}

package() {
  DESTDIR="${pkgdir}" ninja -C build install
}

# vim: ts=2 sw=2 et: