# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: mark.blakeney at bullet-systems dot net

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - comment out extra compile, x86 and doesn't appear to be necessary for ARM

_pipname=debugpy
pkgname=python-$_pipname
pkgver=1.6.2
pkgrel=2
pkgdesc='An implementation of the Debug Adapter Protocol for Python'
arch=(x86_64)
url='https://aka.ms/debugpy'
license=(EPL MIT)
depends=(python)
makedepends=(python-setuptools)
source=(https://github.com/microsoft/debugpy/archive/v$pkgver/$pkgname-$pkgver.tar.gz
        fix-build.patch)
sha256sums=('0fb0b9bdb935b8c129b3cde2b0388d9e47d521e092f8e5b05e5ec5333502ab54'
            'a86e1e1a5a4d7a585c8185721863f563233b680c36fa35d65bfbff11abd519bc')

prepare() {
  cd $_pipname-$pkgver
# remove precompiled libs
  rm src/debugpy/_vendored/pydevd/pydevd_attach_to_process/*.{so,dll,dylib,exe,pdb}

  patch -p1 -i ../fix-build.patch
}

build() {
  cd $_pipname-$pkgver
  python setup.py build
# Compile attach libraries
  #cd build/lib*/debugpy/_vendored/pydevd/pydevd_attach_to_process
  #g++ ${CXXFLAGS} -m64 -shared -o attach_linux_amd64.so -fPIC -nostartfiles linux_and_mac/attach.cpp ${LDFLAGS}
}

package() {
  cd $_pipname-$pkgver
  python setup.py install --skip-build --root="$pkgdir" --optimize=1

  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}