# $Id$
# Maintainer: Sébastien Luttringer
# Contributor: Joel Teichroeb <joel@teichroeb.net>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - export flags for rpi
#  - patch to not call vc_dispmanx_set_wl_buffer_in_use

pkgname=weston
pkgver=1.4.0
pkgrel=2.3
pkgdesc='Reference implementation of a Wayland compositor'
arch=('i686' 'x86_64')
url='http://wayland.freedesktop.org'
license=('MIT')
depends=('libxkbcommon' 'libunwind' 'poppler-glib' 'mtdev' 'libxcursor' 'glu' 'pango' 'colord')
[ "$CARCH" == 'armv6h' ] && makedepends=('raspberrypi-firmware')
source=("http://wayland.freedesktop.org/releases/$pkgname-$pkgver.tar.xz"
	"rpi.patch")
sha1sums=('49b0b6d5e2366a7bad5158b29998213e5ca7f254'
	  '0f4f10111d712b07d7f539aee967b991153aec9f')

build() {
	cd $pkgname-$pkgver
	if [ "$CARCH" == 'armv6h' ]; then
		export RPI_BCM_HOST_LIBS="-L/opt/vc/lib"
		export RPI_BCM_HOST_CFLAGS="-I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
		export WESTON_NATIVE_BACKEND="rpi-backend.so"
		export RPI_COMPOSITOR_LIBS="-ludev -lmtdev -lbcm_host"
		CONFIG='--disable-egl'
		patch -p1 -i ../rpi.patch
	fi
	./configure \
		--prefix=/usr \
		--libexecdir=/usr/lib/weston \
		--enable-demo-clients-install $CONFIG
	make
}

package() {
	cd $pkgname-$pkgver
	make DESTDIR="$pkgdir" install
	# license
	install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}