# U-Boot: Marvell Kirkwood platforms
# Maintainer: Kevin Mihelich <kevin@archlinuxarm.org>

buildarch=2

pkgbase=uboot-kirkwood
pkgname=('uboot-dockstar' 'uboot-goflexhome' 'uboot-goflexnet' 'uboot-pogo_e02')
pkgver=2014.04.R3
pkgrel=1
arch=('arm')
url="https://github.com/archlinuxarm/u-boot"
license=('GPL')
depends=('uboot-env' 'mtd-utils')
source=("https://github.com/archlinuxarm/u-boot/archive/${pkgver##*.}.tar.gz"
        'http://archlinuxarm.org/os/armv5te/boot/dockstar/uboot-dockstar.env'
        'http://archlinuxarm.org/os/armv5te/boot/goflexhome/uboot-goflexhome.env'
        'http://archlinuxarm.org/os/armv5te/boot/goflexnet/uboot-goflexnet.env'
        'http://archlinuxarm.org/os/armv5te/boot/pogo_e02/uboot-pogo_e02.env')
md5sums=('6981030b38375877ff348925bafa60c1'
         '483bb63ff84c05d96e43ec4c85b8d7c2'
         'b9c1acb44e25a45767f31da1f9fd0261'
         '88197b33fee74a31d4914ca4f14007ec'
         'e707982899cebacd64878a87208fa750')

build() {
  cd u-boot-${pkgver##*.}
  
  unset CFLAGS CXXFLAGS LDFLAGS
  
  mkdir bins
  for i in dockstar goflexhome goflexnet pogo_e02; do
    make distclean
    make ${i}_config
    make u-boot.kwb EXTRAVERSION=.${pkgver##*.}-${pkgrel}
    dd if=u-boot.kwb of=bins/uboot-${i}.kwb bs=512k conv=sync
  done;
}

package_uboot-dockstar() {
  pkgdesc="U-Boot for the Seagate FreeAgent DockStar"
  install="$pkgname.install"

  mkdir -p "${pkgdir}"/boot
  cp u-boot-${pkgver##*.}/bins/uboot-dockstar.kwb "${pkgdir}"/boot
  cp "${srcdir}"/uboot-dockstar.env "${pkgdir}"/boot
}

package_uboot-goflexhome() {
  pkgdesc="U-Boot for the Seagate GoFlex Home"
  install="$pkgname.install"

  mkdir -p "${pkgdir}"/boot
  cp u-boot-${pkgver##*.}/bins/uboot-goflexhome.kwb "${pkgdir}"/boot
  cp "${srcdir}"/uboot-goflexhome.env "${pkgdir}"/boot
}

package_uboot-goflexnet() {
  pkgdesc="U-Boot for the Seagate GoFlex Net"
  install="$pkgname.install"

  mkdir -p "${pkgdir}"/boot
  cp u-boot-${pkgver##*.}/bins/uboot-goflexnet.kwb "${pkgdir}"/boot
  cp "${srcdir}"/uboot-goflexnet.env "${pkgdir}"/boot
}

package_uboot-pogo_e02() {
  pkgdesc="U-Boot for the Pogoplug V2 (E02)"
  install="$pkgname.install"

  mkdir -p "${pkgdir}"/boot
  cp u-boot-${pkgver##*.}/bins/uboot-pogo_e02.kwb "${pkgdir}"/boot
  cp "${srcdir}"/uboot-pogo_e02.env "${pkgdir}"/boot
}