# $Id$
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - disable LTO: -DENABLE_LTO='FALSE'

pkgbase=vbam
pkgname=('vbam-sdl' 'vbam-wx')
pkgver=2.0.2
pkgrel=1
pkgdesc='Nintendo GameBoy Advance emulator'
arch=('x86_64')
url='http://vba-m.com'
license=('GPL2')
depends=('gcc-libs' 'glibc' 'libgl' 'libpng' 'sdl2' 'sfml' 'zlib')
makedepends=('cmake' 'ffmpeg' 'wxgtk3' 'zip')
source=("vbam-${pkgver}.tar.gz::https://github.com/visualboyadvance-m/visualboyadvance-m/archive/v${pkgver}.tar.gz")
sha256sums=('f77461faa660b5fd955249087e45dc1dfa87ab8af8208ad7909b424af0879657')

prepare() {
  for p in sdl wx; do
    if [[ -d build-$p ]]; then
      rm -rf build-$p
    fi
    mkdir build-$p
  done
}

build() {
  cd build-sdl

  cmake ../visualboyadvance-m-${pkgver} \
    -DCMAKE_BUILD_TYPE='Release' \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DCMAKE_SKIP_RPATH='TRUE' \
    -DENABLE_SDL='TRUE' \
    -DENABLE_WX='FALSE' \
    -DENABLE_LINK='TRUE' \
    -DENABLE_LTO='FALSE'
  make

  cd ../build-wx

  cmake ../visualboyadvance-m-${pkgver} \
    -DCMAKE_BUILD_TYPE='Release' \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DCMAKE_SKIP_RPATH='TRUE' \
    -DENABLE_SDL='FALSE' \
    -DENABLE_WX='TRUE' \
    -DENABLE_FFMPEG='TRUE' \
    -DENABLE_LINK='TRUE' \
    -DENABLE_LTO='FALSE' \
    -DwxWidgets_CONFIG_EXECUTABLE='/usr/bin/wx-config-gtk3'
  make
}

package_vbam-sdl() {
backup=('etc/vbam.cfg')
conflicts=('vbam-wx')

  cd build-sdl

  make DESTDIR="${pkgdir}" install
}

package_vbam-wx() {
depends+=('glib2' 'gtk3' 'openal' 'wxgtk3' 'zip'
          'libavcodec.so' 'libavformat.so' 'libavutil.so' 'libswscale.so')
conflicts=('vbam-sdl')

  cd build-wx

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: