# $Id: PKGBUILD 53850 2009-10-03 14:55:08Z andrea $
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=audacious
pkgver=2.1
pkgrel=2
pkgdesc="Media player based on BMP"
arch=('i686' 'x86_64')
url="http://audacious-media-player.org/"
license=('GPL3')
depends=('gtk2' 'libmcs' 'dbus-glib' 'libsamplerate' 'libxml2' 'desktop-file-utils'
	'audacious-plugins')
optdepends=('unzip: Zipped skins support')
provides=('audacious-player')
replaces=('audacious-player')
install=audacious.install
source=(http://distfiles.atheme.org/$pkgname-$pkgver.tgz
	'remove_libudet.patch')
md5sums=('03ab6a062e5909214841f90f767f1147'
         'd194f9f187c415b60165dd584ae3bad1')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  patch -Np1 -i ${srcdir}/remove_libudet.patch || return 1

  if [[ $CARCH == "i686" ]]; then
    ./configure --prefix=/usr \
      --enable-samplerate \
      --disable-sse2 || return 1
  elif [[ $CARCH == "x86_64" ]]; then
    ./configure --prefix=/usr \
      --enable-samplerate || return 1
  fi

  make || return 1
  make DESTDIR="$pkgdir" install || return 1
}