# $Id: PKGBUILD 92609 2013-06-10 02:29:07Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: Thomas Dziedzic < gostrc at gmail >

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch for AArch64

pkgname=sunpinyin
pkgver=2.0.3.20130307
_commit=64e26d9ed1f617e59ff37c2efc0be97727c799a1
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="Statistical Language Model based pinyin IME by Sun"
license=('LGPL')
url="http://sunpinyin.googlecode.com"
depends=('sqlite' 'make' 'gcc-libs')
optdepends=('sunpinyin-data: Statistical language model data from open-gram project for sunpinyin')
makedepends=('git' 'scons' 'intltool')
source=("git://github.com/sunpinyin/sunpinyin.git#commit=$_commit"
        'sunpinyin-aarch64.patch')
md5sums=('SKIP'
         'b6de843feb134e6bfbf0eb53e81df551')

prepare() {
  cd "$srcdir/$pkgname"
  patch -p1 -i ../sunpinyin-aarch64.patch
}

build() {
  cd "$srcdir/$pkgname"
  sed -i -e "1s|python|python2|" python/*.py python/importer/*.py

  scons \
    --prefix=/usr
}

package() {
  cd "$srcdir/$pkgname"

  scons \
    --prefix=/usr \
    --install-sandbox="$pkgdir" \
    install
}