# Maintainer: Ben Ruijl <benruyl at gmail>

pkgname=couchpotato-git
pkgver=1796.0eff4f0
pkgver() {
	cd "$srcdir/$pkgname"
	echo $(git rev-list --count master).$(git rev-parse --short master)
}
epoch=1
pkgrel=1
pkgdesc="Automatic Movie Downloading via NZBs & Torrent"
arch=('i686' 'x86_64')
url="http://couchpota.to/"
license=('unknown')
depends=('python2')
makedepends=('git')
install='couchpotato.install'
backup=('etc/conf.d/couchpotato' 'etc/conf.d/couchpotato_systemd')
source=('couchpotato' 'couchpotato.init' 'couchpotato.conf' 'couchpotato_systemd.conf' 'couchpotato.service' "$pkgname::git://github.com/RuudBurger/CouchPotatoServer.git")
md5sums=('a7db842a8af532847ef41890f6714819'
         'a7711d04d2db7de96f067e484c29f709'
         '2c3c045ae9c5f5bf4bc0972917c19071'
         'c22c7a797415131baf0fbe092132abda'
         'bdedef6bcb8d04c534bd094047885fa7'
         'SKIP')


package() {
  install -d "${pkgdir}/opt/"
  cp -dpr --no-preserv=ownership "$srcdir/$pkgname" "${pkgdir}/opt/couchpotato"

  install -D -m755 "${srcdir}/couchpotato" "${pkgdir}/usr/bin/couchpotato"
  install -D -m755 "${srcdir}/couchpotato.init" "${pkgdir}/etc/rc.d/couchpotato"
  install -D -m644 "${srcdir}/couchpotato.conf" "${pkgdir}/etc/conf.d/couchpotato"
  install -D -m644 "${srcdir}/couchpotato_systemd.conf" "${pkgdir}/etc/conf.d/couchpotato_systemd"
  install -D -m644 "${srcdir}/couchpotato.service" "${pkgdir}/usr/lib/systemd/system/couchpotato.service"
}