# Maintainer: graysky <graysky@archlinux.us>

buildarch=12

pkgname=rpi-eeprom
_commit=f19990103e4483ebb47be5ea897c134913f83ad8
pkgver=20210708
pkgrel=1
pkgdesc="Bootloader and VL805 USB controller EEPROM update tool for RPi4"
arch=('any')
url='https://github.com/raspberrypi/rpi-eeprom'
license=('custom')
depends=(python pciutils raspberrypi-firmware coreutils binutils)
backup=("etc/default/$pkgname-update")
source=("https://github.com/raspberrypi/rpi-eeprom/archive/$_commit.tar.gz")
md5sums=('e27a9daa8865e5a04e568f1aa52e1a2d')

package() {
  cd "$pkgname-$_commit"
  install -pd "$pkgdir/usr/bin"
  install -pm755 rpi-eeprom-config "$pkgdir/usr/bin/rpi-eeprom-config"
  install -pm755 rpi-eeprom-update "$pkgdir/usr/bin/rpi-eeprom-update"
  install -pDm644 "$pkgname-update-default" "$pkgdir/etc/default/$pkgname-update"

  # Arch ARM does not ship raspi-config
  sed -i '/to change the release/d' "$pkgdir/usr/bin/rpi-eeprom-update"

  install -pd "$pkgdir/usr/lib/firmware/raspberrypi/bootloader/backup"
  for target in beta critical stable; do
    cp -a "firmware/$target" "$pkgdir/usr/lib/firmware/raspberrypi/bootloader"
  done
  ln -sf critical "$pkgdir/usr/lib/firmware/raspberrypi/bootloader/default"
  ln -sf stable "$pkgdir/usr/lib/firmware/raspberrypi/bootloader/latest"

  install -pDm644 LICENSE "$pkgdir/usr/share/doc/$pkgname"
}