# $Id: PKGBUILD 52525 2009-09-21 10:53:18Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>

pkgname=vlc
pkgver=1.0.2
pkgrel=1
pkgdesc="A multi-platform MPEG, VCD/DVD, and DivX player"
arch=('i686' 'x86_64')
url="http://www.videolan.org/vlc/"
license=('GPL')
depends=('a52dec' 'fluidsynth' 'libmtp' 'libdvbpsi' 'lirc-utils' 'libdca' 'qt'
         'libproxy' 'sdl_image' 'libdvdnav>=4.1.3' 'lua' 'libv4l' 'libcddb' 
	 'smbclient' 'libmatroska' 'taglib' 'sysfsutils' 'libmpcdec' 'hal' 
	 'ffmpeg>=0.5' 'libshout' 'libmad' 'fribidi' 'libmpeg2' 'libmodplug' 
	 'avahi' 'ttf-dejavu' 'libxv' 'libass' 'xdg-utils')
makedepends=('pkgconfig' 'live-media>=2009.06.02')
optdepends=('libnotify')
options=('!libtool')
install=vlc.install
source=(http://download.videolan.org/pub/videolan/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.bz2)
md5sums=('69d4e30fe4fc2691780fbeacd40359d2')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  sed -i -e 's:/usr/share/fonts/truetype/freefont/FreeSerifBold.ttf:/usr/share/fonts/TTF/DejaVuSerif-Bold.ttf:' modules/misc/freetype.c
  [ "${CARCH}" = "i686" ] && EXTRAFEATURES="--enable-loader --enable-live555 --with-live555-tree=/usr/lib/live-media"
  [ "${CARCH}" = "x86_64" ] && EXTRAFEATURES="--enable-fast-install --enable-live555 --with-live555-tree=/usr/lib/live-media"
  ./configure --prefix=/usr \
              --enable-libass \
              --enable-dvdread \
	      --enable-jack \
              --enable-dvdnav \
              --disable-rpath \
	      --disable-zvbi \
              --enable-qt4 \
              --enable-faad \
              --enable-alsa \
              --enable-skins2 \
              --enable-dvb \
              --enable-v4l \
              --enable-theora \
              --enable-flac \
              --enable-snapshot \
              --enable-hal \
              --enable-dbus \
              --enable-ogg \
              --enable-dbus-control \
              --enable-shared \
              --enable-nls \
              --enable-lirc \
              --enable-shout \
              --enable-pvr \
              --enable-release \
              --program-suffix= \
	      --enable-realrtsp ${EXTRAFEATURES} || return 1
  CFLAGS="-fPIC"
  make || return 1
  make DESTDIR=${pkgdir}/ install || return 1
  
  for res in 16 32 48 128; do
    install -D -m644 ${srcdir}/vlc-${pkgver}/share/vlc${res}x${res}.png \
		     ${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png || return 1
  done
  rm -rf ${pkgdir}/usr/lib/mozilla
}