# $Id$
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Tobias Kieslich <tobias@archlinux.org>
# Contributor: Martin Sugioarto <nakal@web.de>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch for signed char

pkgname=gimp-ufraw
pkgver=0.22
pkgrel=9
pkgdesc='Converter for raw files; utility and GIMP plugin'
url='http://ufraw.sourceforge.net/'
arch=('x86_64' 'i686')
license=('GPL')
depends=('gtkimageview' 'exiv2' 'lcms' 'desktop-file-utils' 'cfitsio' 'lensfun')
makedepends=('gimp' 'cinepaint')
optdepends=('gimp: to use the gimp import plugin for raw images'
            'cinepaint: to use the cinepaint import plugin for raw images')
source=("http://downloads.sourceforge.net/ufraw/ufraw-$pkgver.tar.gz"
        '05_fix_build_due_to_unsigned_char.patch')
sha256sums=('f7abd28ce587db2a74b4c54149bd8a2523a7ddc09bedf4f923246ff0ae09a25e'
            'abd049d66639a3af8686c7e82ff39c8f07d05fdef37fb83bef23be25e467ef54')

prepare() {
  # One of the include files that comes with cinepaint requires
  # ../lib/wire/ to exist...
  mkdir -p lib
  ln -s /usr/include/cinepaint/wire lib/wire

  patch -p1 -d "ufraw-$pkgver" -i ../05_fix_build_due_to_unsigned_char.patch
}

build() {
  cd "ufraw-$pkgver"

  ./configure \
    --prefix=/usr \
    --enable-extras \
    --enable-mime \
    --enable-openmp \
    --with-gimp \
    --with-cinepaint \
    --enable-contrast
  sed -i "s/-ffast-math -fomit-frame-pointer -W -Wall -O3/${CFLAGS}/" Makefile
  make
}

package() {
  make -C "ufraw-$pkgver" DESTDIR="$pkgdir" install
  rm -f "$pkgdir/usr/bin/dcraw"
}

# vim:set ts=2 sw=2 et: