# $Id: PKGBUILD 182399 2013-04-10 05:34:09Z pierre $
# Maintainer: Pierre Schmitz <pierre@archlinux.de>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patches to fix issues with how we use the tools

pkgname=devtools-alarm
_pkgname=devtools
pkgver=20131107
pkgrel=3
pkgdesc='Tools for Arch Linux ARM package maintainers'
arch=('any')
license=('GPL')
url='http://projects.archlinux.org/devtools.git/'
conflicts=('devtools')
provides=('devtools')
depends=('namcap' 'openssh' 'subversion' 'rsync' 'arch-install-scripts')
source=("ftp://ftp.archlinux.org/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
        "ftp://ftp.archlinux.org/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz.sig"
        '0001-makechrootpkg-cache-dir.patch'
        '0002-arch-nspawn-keep-mirrorlist.patch'
        '0003-makechrootpkg-distcc.patch'
        '0004-arch-nspawn-arm-fix.patch'
        '0005-makechrootpkg-no-default-logging.patch'
        '0006-archbuild-no-setarch.patch')
md5sums=('8b78e5f8e68d09864cf231c999ab222a'
         'SKIP'
         '7b96700206f0832d8f9c72adeccb8f9f'
         'ac6a4477565030c8e2bea08068e7597f'
         '97a011ae19be82b932ef8abab83f9b6a'
         'd7c5800ed19500e33e2c9cf89c41a86c'
         '473f7128e088188121f5565e7ca34759'
         'a9f511668f1f8bb8f408017ec7dbabc9')

prepare() {
	cd ${srcdir}/${_pkgname}-${pkgver}
	patch -p1 -i "${srcdir}"/0001-makechrootpkg-cache-dir.patch
	patch -p1 -i "${srcdir}"/0002-arch-nspawn-keep-mirrorlist.patch
	patch -p1 -i "${srcdir}"/0003-makechrootpkg-distcc.patch
	patch -p1 -i "${srcdir}"/0004-arch-nspawn-arm-fix.patch
	patch -p1 -i "${srcdir}"/0005-makechrootpkg-no-default-logging.patch
	patch -p1 -i "${srcdir}"/0006-archbuild-no-setarch.patch
}

build() {
	cd ${srcdir}/${_pkgname}-${pkgver}
	make PREFIX=/usr
}

package() {
	cd ${srcdir}/${_pkgname}-${pkgver}
	make PREFIX=/usr DESTDIR=${pkgdir} install
}