# $Id$
# Maintainer: Kyle Keen <keenerd@gmail.com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch to not build neon on !ARMv7

pkgname=libvolk
pkgver=1.3
pkgrel=2
pkgdesc="The Vector-Optimized Library of Kernels from Gnuradio"
arch=('i686' 'x86_64')
url="http://libvolk.org/"
license=('GPL3')
depends=('gcc-libs' 'boost-libs' 'orc' 'python2')
makedepends=('boost' 'cmake' 'python2-cheetah')
source=("http://libvolk.org/releases/volk-$pkgver.tar.gz"
        '0001-Use-NEON-for-ARMv7-only.patch')
md5sums=('d04edc0779431c8660a8a592792a3680'
         'da3b1d0b0f859697c743563ee55152d3')

# doxygen for docs

prepare() {
  cd "$srcdir/volk-$pkgver"
  sed -i -e "s|#![ ]*/usr/bin/env python$|&2|" $(find ./ -name '*.py')
  patch -p1 -i ../0001-Use-NEON-for-ARMv7-only.patch
}

build() {
  export PYTHON=python2
  cd "$srcdir/volk-$pkgver"

  mkdir -p build
  cd build
  cmake \
    -DPYTHON_EXECUTABLE=$(which python2) \
    -DCMAKE_INSTALL_PREFIX=/usr -Wno-dev ../
  make
}

check() {
  cd "$srcdir/volk-$pkgver/build"
  export PYTHON=python2
  if [[ "$CARCH" == "x86_64" ]]; then
    make test
  fi
}

package() {
  cd "$srcdir/volk-$pkgver/build"
  make DESTDIR="$pkgdir" install
}