# Maintainer: graysky <therealgraysky AT protonmail DOT com>

pkgname=raspberrypi-utils
pkgver=20240203
pkgrel=2
_commit=b5191011dd47e22e4d6ca99fd6acef6004994a6b
pkgdesc="Legacy scripts and simple applications for Raspberry Pi"
arch=('aarch64' 'armv7h')
url="https://github.com/raspberrypi/utils"
license=('custom')
makedepends=('cmake' )
depends=('dtc')
replaces=('raspberrypi-firmware')
conflicts=('raspberrypi-firmware')
options=(!strip)
source=("utils-$pkgver-$pkgrel-${_commit:0:10}.tar.gz::https://github.com/raspberrypi/utils/archive/$_commit.tar.gz"
         10-raspberrypi-utils.rules
         0001-Revert-dtmerge-Make-i2c_arm-vc-creation-conditional.patch
)
md5sums=('2c54ac5fb4295da4cfc8d37106418458'
         'a0423d9850cc56a15967e103c351c335'
         '5cab163f641a28e258740a6ba3b13021')

prepare() {
  cd "utils-$_commit"
  patch -p1 -i ../0001-Revert-dtmerge-Make-i2c_arm-vc-creation-conditional.patch
}

build() {
  cd "utils-$_commit"
  cmake -S . -B . -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd "utils-${_commit}"
  make install DESTDIR="$pkgdir"
  install -Dm0644 LICENCE -t "$pkgdir/usr/share/licenses/$pkgname"

  # setup permissions on video group for /usr/bin/vcgencmd
  install -Dm0644 ../10-raspberrypi-utils.rules "$pkgdir/usr/lib/udev/rules.d/10-raspberrypi-utils.rules"
}