# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Maintainer: Andreas Radke <andyrtr@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - add mesa makedepend

pkgname='mesa-demos'
pkgver=8.1.0
pkgrel=2
arch=('i686' 'x86_64')
pkgdesc="Mesa demos and tools"
url="http://mesa3d.sourceforge.net"
license=('custom')
depends=('libgl' 'glew')
makedepends=('mesa')
source=("ftp://ftp.freedesktop.org/pub/mesa/demos/${pkgver}/mesa-demos-${pkgver}.tar.bz2"
        'LICENSE'
        drawtex-resolve-glDrawTexfOES-extension-function.patch)
sha256sums=('9703fa0646b32a1e68d2abf5628f936f77bf97c69ffcaac90de380820a87a828'
            '7fdc119cf53c8ca65396ea73f6d10af641ba41ea1dd2bd44a824726e01c8b3f2'
            '963b3e45b2eccafea50fdab4f2fac17bd308f4c15522c00d4787b50ebb25423a')

prepare() {
  cd "${srcdir}/mesa-demos-${pkgver}"
  # merged upstream
  patch -Np1 -i ../drawtex-resolve-glDrawTexfOES-extension-function.patch
}

build() {
  cd "${srcdir}/mesa-demos-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/mesa-demos-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/mesa-demos"
  install -m755 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-demos/"
}