# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Maintainer: Robin Candau <antiz@archlinux.org>
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: mlq <mlq@pwmt.org>

# ALARM: David Beauchamp <david@archlinuxarm.org>
#  - moved xorg-server-xvfb from checkdepends to makedepends

pkgname=girara
pkgver=0.4.4
pkgrel=1
pkgdesc="User interface library focused on simplicity and minimalism"
url="https://pwmt.org/projects/girara"
arch=('x86_64')
license=('Zlib')
provides=('girara-gtk3' 'girara-common')
replaces=('girara-gtk3' 'girara-common')
conflicts=('girara-gtk3' 'girara-common')
depends=('gtk3' 'glib2' 'json-glib' 'pango' 'glibc')
makedepends=('meson' 'ninja' 'doxygen' 'check' 'xorg-server-xvfb')
#checkdepends=('xorg-server-xvfb')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/pwmt/${pkgname}/archive/refs/tags/${pkgver}.tar.gz")
sha512sums=('4c106c2156ff397caad2c173cbfb5f2dc8f4574a59c70e7d04e941fd5273948c7e2cc4662b91a489dc689e6537b72bdb1771849cf7775d6afa167f2616a3d4c7')

build() {
        cd "${pkgname}-${pkgver}"
        arch-meson build
        ninja -C build
}

check() {
        cd "${pkgname}-${pkgver}"
        ninja -C build test
}

package() {
        cd "${pkgname}-${pkgver}"
        DESTDIR="${pkgdir}" ninja -C build install
        install -Dm 664 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}