# $Id: PKGBUILD 99895 2013-10-31 02:20:19Z allan $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Darwin Bautista <djclue917@gmail.com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - increase maximum allocation pool to 512MB to fix AArch64 build

pkgname=belle-sip
pkgver=1.6.1
pkgrel=1
pkgdesc="A Voice-over-IP phone"
arch=('i686' 'x86_64')
url="https://github.com/BelledonneCommunications/belle-sip/"
license=('GPL')
depends=('libantlr3c' 'gcc-libs' 'mbedtls' 'bctoolbox')
makedepends=('java-runtime')
options=('!emptydirs')
source=("$pkgname-$pkgver.tar.gz::https://github.com/BelledonneCommunications/belle-sip/archive/$pkgver.tar.gz"
	"antlr.jar::https://github.com/antlr/website-antlr3/blob/gh-pages/download/antlr-3.4-complete.jar?raw=true")
noextract=('antlr.jar')
sha256sums=('60ea452d21403f59dd78fce9f385de81666e14b6b5e2533505e635611479c52e'
            '9d3e866b610460664522520f73b81777b5626fb0a282a5952b9800b751550bf7')

prepare() {
  cd $pkgname-$pkgver
  sed -i \
    -e "s#antlr_java_prefixes=.*#antlr_java_prefixes="$srcdir"#" \
    -e "s|-Werror||g" \
    configure.ac
  sed -i \
    -e 's|bctbx_list_delete_link|bctbx_list_erase_link|g' \
    -e 's|bctbx_list_remove_link|bctbx_list_unlink|g' \
    include/belle-sip/list.h
  sed -i 's|, super->base.peer_cname ? super->base.peer_cname : super->base.peer_name ||' src/transports/tls_channel.c
  sed -i 's/Xmx256m/Xmx512m/' configure.ac
}

build() {
  cd $pkgname-$pkgver
  [ -x ./configure ] || ./autogen.sh
  ./configure --prefix=/usr  --libexecdir=/usr/lib/$pkgname \
    --disable-tests --disable-static --enable-tls
  make
}

package() {
  cd "$srcdir"/$pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}