# Maintainer: Alexander Foremny <alexanderforemny@gmail.com>

pkgname=e2fsprogs
pkgver=1.41.4
pkgrel=1
pkgdesc="Ext2/3/4 filesystem utilities"
arch=('arm')
license=('GPL' 'LGPL' 'MIT')
url="http://e2fsprogs.sourceforge.net"
groups=('base')
depends=('glibc')
makedepends=('bc' 'gawk' 'make')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.gz
	'Makefile-fsck.static.patch')
backup=('etc/mke2fs.conf')
md5sums=('59033388df36987d2b9c9bbf7e19bd57'
         'ce2b0daf84e17e8c7880ba3d43020ea3')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  # Remove unnecessary init.d directory
  sed -i '/init\.d/s|^|#|' misc/Makefile.in

  ./configure --prefix=/usr --with-root-prefix="" --enable-elf-shlibs
  
  # add fsck.static for mkinitrd use
  patch -Np1 -i ../Makefile-fsck.static.patch || return 1
  
  make || return 1
  make DESTDIR=${pkgdir} install install-libs || return 1
  make -C ${srcdir}/${pkgname}-${pkgver}/misc fsck.static || return 1
  
  install -D -m755 ${srcdir}/${pkgname}-${pkgver}/misc/fsck.static \
	 ${pkgdir}/sbin/fsck.static || return 1
  
  sed -i -e 's/^AWK=.*/AWK=awk/' ${pkgdir}/usr/bin/compile_et || return 1
}