# Maintainer: Morten Linderud <foxboron@archlinux.org>
# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
# Maintainer: Anatol Pomozov

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - removed AUTOBAHN_USE_NVX=1 from python build/install commands

pkgname=python-autobahn
pkgver=19.8.1
pkgrel=1
pkgdesc='Real-time framework for Web, Mobile & Internet of Things'
arch=(x86_64)
url='https://crossbar.io/autobahn/'
license=(MIT)
depends=(python-cffi python-twisted python-six python-txaio python-wsaccel
         python-setuptools python-cryptography)
makedepends=(python-argon2_cffi python-cbor python-flatbuffers
             python-msgpack python-passlib python-pynacl python-ubjson)
checkdepends=(python-mock python-pytest python-pytest-asyncio)
optdepends=(
  'python-cbor: CBOR serializer support'
  'python-flatbuffers: FlatBuffers serializer support'
  'python-msgpack: MsgPack serializer support'
  'python-ubjson: UBJSON serializer support'
  'python-argon2_cffi: WAMP-SCRAM authentication support'
  'python-passlib: WAMP-SCRAM authentication support'
  'python-pynacl: WAMP-cryptosign support'
)

source=(https://files.pythonhosted.org/packages/source/a/autobahn/autobahn-$pkgver.tar.gz)
sha256sums=('294e7381dd54e73834354832604ae85567caf391c39363fed0ea2bfa86aa4304')

build() {
  cd "$srcdir/autobahn-$pkgver"
  python setup.py build
}

check() {
  cd "$srcdir/autobahn-$pkgver"
  pyver=$(python -c "import sys; print('{}.{}'.format(*sys.version_info[:2]))")
  # test_depleting checks whether the entropy on the running machine can be depleted or not.
  # Unrelated to autobahn and makes the test suite flaky
  USE_TWISTED=1 PYTHONPATH=.:build/lib.linux-$CARCH-$pyver pytest -v autobahn -k 'not test_depleting'
  USE_ASYNCIO=1 PYTHONPATH=.:build/lib.linux-$CARCH-$pyver pytest -v autobahn -k 'not test_depleting'
}

package() {
  cd "$srcdir/autobahn-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}