# Maintainer: Jan Madaj < madaj.jan@gmail.com >

#alarm: moonman
#    -dkms.conf: change ARCH=i386 to ARCH=arm
#    -depends on linux-headers >=3.7 because of the patch
#     don't know if it works with earlier kernels

buildarch=2

pkgname=dkms-8192cu
pkgver=v3.4.4_4749
pkgrel=7
pkgdesc="Driver for Realtek RTL8188CUS (8188C, 8192C) chipset wireless cards"
arch=('arm')
url="http://www.realtek.com.tw/"
license=('GPL')
depends=('dkms' 'linux-headers>=3.7')
conflicts=("8192cu" "rt8192cu")
install=${pkgname}.install
options=(!strip)
_pkgname="8192cu"
source=("https://www.dropbox.com/s/3rrxrg55hmnzr1l/$_pkgname-$pkgver.tar.bz2"
		"dkms.conf"
		"blacklist-dkms-8192cu.conf"
		"use_kthread_run.patch"
		"use_kthread_run_v2.patch" )
		
md5sums=('f4291ba24e9ff3408c26606ba9400152'
		 '9de2f7a7788689e2bf7680950b4451d9'
		 '5f2d28bf3839447bfe762416a89e1a21'
		 '28acff14c65b67e7ec246173cae113c0'
		 '7b22f83c62456e4b8310e21b56bb4c2f')



package() {
	
	installDir="$pkgdir/usr/src/$_pkgname-$pkgver"
	
	install -dm755 "$installDir"
	install -m644 "$srcdir/dkms.conf" "$installDir"
	install -dm755 "$pkgdir/etc/modprobe.d"
	install -m644 "$srcdir/blacklist-dkms-8192cu.conf" "$pkgdir/etc/modprobe.d/blacklist-dkms-8192cu.conf"
 	
 	cd "${srcdir}/${_pkgname}-${pkgver}/"
 	
 	patch -p1 -i "$srcdir/use_kthread_run_v2.patch"
 	
 	for d in `find . -type d`
 	do
		install -dm755  "$installDir/$d"
	done
	
	for f in `find . -type f`
	do
		install -m644 "${srcdir}/${_pkgname}-${pkgver}/$f" "$installDir/$f"
	done
	
}