# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Conributor: Mélanie Chauvel (ariasuni) <perso at hack-libre dot org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - remove makedepend on pandoc

pkgname=nuspell
pkgver=4.2.0
pkgrel=3
pkgdesc='Fast and safe spellchecking C++ library'
arch=('x86_64')
url='https://nuspell.github.io/'
license=('LGPL3')
depends=('icu')
#makedepends=('cmake')
makedepends=('cmake' 'ruby-ronn')
checkdepends=('catch2')
source=(${pkgname}-${pkgver}.tar.gz::"https://github.com/nuspell/nuspell/archive/v${pkgver}.tar.gz"
        ${pkgname}-pandoc.patch::https://github.com/nuspell/nuspell/commit/5d4f685011b2.patch)
sha512sums=('ae9157e9753868c002ed69a765fb705d29d993f3940e11efbc2699778a8b1abee2eb7daa0ff51187b899d6935a215a24662e5b52ec1ef5c644e90a0245f7583d'
            'SKIP')



prepare() {
  mkdir build
  # temporarily use ronn - pandoc is unusable due to a separate haskell rebuild
  patch -Rp1 -f -d ${pkgname}-${pkgver} <${pkgname}-pandoc.patch || /bin/true
}

build() {
  cd build
  cmake ../${pkgbase}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DBUILD_SHARED_LIBS=ON
  make
}

check() {
  cd build
  make test
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}