# $Id: PKGBUILD 3340 2009-10-02 13:30:17Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: tobias <tobias@archlinux.org>
# Committer: Manolis Tzanidakis <manolis@archlinux.org>
# Contributor: Simon Lackerbauer <calypso "at"   strpg.org> 

pkgname=phpmyadmin
pkgver=3.2.2
pkgrel=3
pkgdesc="A PHP and hence web-based tool to administrate MySQL over the WWW"
arch=('any')
url="http://www.phpmyadmin.net"
license=('GPL')
depends=('mysql-clients' 'php')
optdepends=('libmcrypt: to use phpMyAdmin internal authentication')
backup=(etc/webapps/phpmyadmin/.htaccess \
        etc/webapps/phpmyadmin/config.inc.php)
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/phpMyAdmin-$pkgver-all-languages.tar.bz2)
md5sums=('a5f6492f89ee1ff17b76593af79640ce')

build() {
  _instdir=${startdir}/pkg/usr/share/webapps/phpMyAdmin
  mkdir -p ${_instdir} $pkgdir/etc/webapps/phpmyadmin
  cd ${_instdir}

  cp -ra ${startdir}/src/phpMyAdmin-${pkgver}-all-languages/* . && \
  echo "deny from all" >$pkgdir/etc/webapps/phpmyadmin/.htaccess || return 1

  ln -s /etc/webapps/phpmyadmin/.htaccess ${_instdir}/.htaccess && \
  ln -s /etc/webapps/phpmyadmin/config.inc.php ${_instdir}/config.inc.php && \
  cp ${_instdir}/config.sample.inc.php $pkgdir/etc/webapps/phpmyadmin/config.inc.php && \
  cp ${_instdir}/config.sample.inc.php $pkgdir/etc/webapps/phpmyadmin/ || return 1

  # apache
  cat >$pkgdir/etc/webapps/phpmyadmin/apache.example.conf <<EOF
	Alias /phpmyadmin/ "/usr/share/webapps/phpMyAdmin/"
	<Directory "/usr/share/webapps/phpMyAdmin">
		AllowOverride All
		Options FollowSymlinks
		Order allow,deny
		Allow from all
	</Directory>
EOF
}