# $Id: PKGBUILD 27366 2009-02-20 00:14:36Z aaron $
# Maintainer : Aaron Griffin <aaron@archlinux.org>

pkgname=bootchart
pkgver=0.9
pkgrel=5
pkgdesc="Boot Process Performance Visualization"
url="http://www.bootchart.org/"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('acct' 'sh')
optdepends=('java-runtime: for bootchart-render')
makedepends=('apache-ant')
install=bootchart.install
source=(http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.bz2
        bootchart-render
        #FS#8438 - fix the regex used to scan inittab for archlinux
        fix-inittab-regex.patch)
md5sums=('4be91177d19069e21beeb106f2f77dff'
         'f02888cda23a5b1c9b931140f6fdbb71'
         'c8a70f1f763a2632dc7759a6387f865f')

build()
{
  cd $startdir/src/$pkgname-$pkgver
  patch -up1 < $startdir/src/fix-inittab-regex.patch
  ant
  sed -i "s#ROOT=/#ROOT=$startdir/pkg#" install.sh

  mkdir -p $startdir/pkg/sbin
  mkdir -p $startdir/pkg/etc
  ./install.sh

  chmod 644 $startdir/pkg/etc/bootchartd.conf

  mkdir -p $startdir/pkg/usr/share/bootchart
  cp bootchart.jar $startdir/pkg/usr/share/bootchart

  mkdir -p $startdir/pkg/usr/bin
  install -m755 $startdir/src/bootchart-render $startdir/pkg/usr/bin/bootchart-render
}