# $Id: PKGBUILD 48508 2009-08-02 20:47:30Z tpowa $
# Maintainer : Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Morgan LEFIEUX <comete@archlinuxfr.org>

pkgname=hplip
pkgver=3.9.6b
pkgrel=2
pkgdesc="Drivers for HP DeskJet, OfficeJet, Photosmart, Business Inkjet and some LaserJet."
arch=('i686' 'x86_64')
url="http://hplipopensource.com"
license=('GPL')
makedepends=('pyqt' 'pkgconfig' 'sane' 'rpcbind' 'dbus-python' 'cups')
depends=('python' 'ghostscript>=8.64-6' 'foomatic-db' 'foomatic-db-hpijs' \
         'foomatic-db-engine' 'libcups>=1.3.10-3' 'net-snmp>=5.4')
replaces=('hpijs')
options=('!libtool')
install=hplip.install
source=(http://downloads.sourceforge.net/sourceforge/hplip/$pkgname-$pkgver.tar.gz)
optdepends=('cups: for printing support'
            'dbus-python: for dbus support'
            'sane: for scanner support'
            'portmap: for network support'
            'pyqt: for running hp-toolbox')

build() {
 cd $srcdir/$pkgname-$pkgver
 ./configure --prefix=/usr --enable-qt4 --enable-foomatic-rip-hplip-install \
             --enable-foomatic-ppd-install --enable-hpcups-install \
             --enable-cups-drv-install --enable-hpijs-install \
             --enable-foomatic-drv-install
 make || return 1
 make DESTDIR=$pkgdir/ install

 rm -rf $pkgdir/etc/sane.d
 # remove autostart of hp-daemon
 rm -r $pkgdir/etc/xdg
 # move udev rules to /lib/udev/rules.d
 mkdir -p $pkgdir/lib/udev/rules.d
 mv $pkgdir/etc/udev/rules.d/* $pkgdir/lib/udev/rules.d/
 rm -r $pkgdir/etc/udev
 # remove lp user, it's not used on archlinux
 sed -i 's|OWNER="lp", ||g' $pkgdir/lib/udev/rules.d/55-hpmud.rules
}
md5sums=('49a87fe7d7a57a075ed9631113cee662')