# Maintainer: Firmicus <firmicus āt gmx dōt net>

pkgname=texlive-langextra
pkgver=2009.14322
pkgrel=3
pkgdesc="TeX Live - Bundle of all extra language support"
license=('GPL')
arch=(any)
conflicts=('texlive-langafrican' 'texlive-langarab' 'texlive-langarmenian' 'texlive-langcroatian' 'texlive-langhebrew' 'texlive-langindic' 'texlive-langmongolian' 'texlive-langtibetan' 'texlive-langvietnamese') 
provides=('texlive-langafrican' 'texlive-langarab' 'texlive-langarmenian' 'texlive-langcroatian' 'texlive-langhebrew' 'texlive-langindic' 'texlive-langmongolian' 'texlive-langtibetan' 'texlive-langvietnamese') 
depends=('texlive-latexextra')
groups=('texlive-lang')
url='http://tug.org/texlive/'
source=("ftp://ftp.archlinux.org/other/texlive/$pkgname-$pkgver-src.zip" "$pkgname.maps")
options=('!emptydirs')
install=texlive.install
md5sums=('f5033bf615cf1d8155cec928845aea38'
         '19385050c1b5d3af3643cd765f32d32f')

build() {
   cd $srcdir
   install -m755 -d $pkgdir/usr/share/texmf-var/arch/installedpkgs || return 1
   sed -i '/^#/d' CONTENTS || return 1
   _revnr=`echo $pkgver | sed 's/2009\.//'`
   install -m644 CONTENTS $pkgdir/usr/share/texmf-var/arch/installedpkgs/${pkgname}_${_revnr}.pkgs || return 1
   install -m644 $pkgname.maps $pkgdir/usr/share/texmf-var/arch/installedpkgs/ || return 1
   for p in *.tar.xz; do 
	   bsdtar -xf $p || return 1
   done
   rm -rf {tlpkg,doc,source}
   install -m755 -d $pkgdir/usr/share || return 1
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done)
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \; || return 1
     find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \; || return 1
   done
   if [[ -d texmf-dist ]]; then
     find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \; || return 1
     find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \; || return 1
   fi
   if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
     find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
   install -m755 -d $pkgdir/usr/bin || return 1   
   ln -s /usr/share/texmf-dist/scripts/bengali/ebong.py $pkgdir/usr/bin/ebong
}