# $Id$
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Thomas Jost <schnouki@schnouki.net>
# Contributor: JaDa <jada@archlinux.us>
# Contributor: Joaquim Pedro <osmano807@gmail.com>
# Contributor: Jan Rüegg <rggjan@gmail.com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - hack to skip using v7 assembly on v6

pkgname=gperftools
pkgver=2.2
pkgrel=1
pkgdesc="Fast, multi-threaded malloc() and nifty performance analysis tools"
arch=('i686' 'x86_64')
url="http://code.google.com/p/gperftools/"
license=('BSD')
depends=('perl')
provides=('libtcmalloc.so'
          'libprofiler.so'
          'libtcmalloc_debug.so'
          'libtcmalloc_and_profiler.so'
          'libtcmalloc_minimal.so'
          'libtcmalloc_minimal_debug.so')
makedepends=('git')
optdepends=('graphviz: pprof graph generation'
            'gv: pprof postscript generation')
options=('!libtool')
source=("git+https://code.google.com/p/gperftools#tag=gperftools-$pkgver"
        "armv6.patch")
sha256sums=('SKIP'
            '879a6e92947a5538885b9e63c2675a93d57870f58c2d61260fec91ce56823df8')

prepare() {
  cd "$pkgname"

  patch -p1 -i ../armv6.patch
  ./autogen.sh
}

build() {
  cd "$pkgname"

  ./configure --prefix=/usr --enable-frame-pointers
  make
}

package() {
  cd "$pkgname"

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}

# vim:set ts=2 sw=2 et: