# Maintainer: Tobias Powalowski <tpowa@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch from OpenSUSE to fix AArch64 FTBFS

pkgname=dmapi
pkgver=2.2.12
pkgrel=6
pkgdesc="Data migration API"
arch=('x86_64')
url="http://oss.sgi.com/projects/xfs/"
license=('GPL-2.0-or-later')
depends=('glibc')
makedepends=('xfsprogs')
provides=('xfsdmapi')
conflicts=('xfsdmapi')
replaces=('xfsdmapi')
#source=("ftp://oss.sgi.com/projects/xfs/previous/cmd_tars/$pkgname-$pkgver.tar.gz" dmapi-headers.patch)
source=(https://sources.archlinux.org/other/packages/dmapi/dmapi-$pkgver.tar.gz dmapi-headers.patch no-getdents-aarch64.diff)

prepare() {
  cd $pkgname-$pkgver
  patch -p1 -i ../dmapi-headers.patch # Fix build (Gentoo)
  patch -p0 -i ../no-getdents-aarch64.diff
}

build() {
  cd dmapi-$pkgver
  [ "$CARCH" = "x86_64" ] && export CFLAGS="$CLFAGS -fPIC"
  export INSTALL_USER=root
  export INSTALL_GROUP=root
  export DEBUG=-DNDEBUG
  autoconf
  ./configure --prefix=/usr
  make
}

package() {
  cd dmapi-$pkgver
  make DIST_ROOT="$pkgdir" install install-dev
  # the static lib
  install -D -m644 libdm/.libs/libdm.a "$pkgdir"/usr/lib/libdm.a
  # and the header file, please
  install -D -m644 include/dmapi.h "$pkgdir"/usr/include/xfs/dmapi.h
  # kill libexec dir
  rm -rf "$pkgdir"/usr/libexec
}
sha256sums=('b18e34f47374f6adf7c164993c26df36986a009b86aa004ef9444102653aea69'
            'c5935312dd4d77156da023776c93036fa7989ce78ff8b9f6d9421c31a5535647'
            'd6fda996d6258aa95ccca2dbbb02cc3dff6a45940edd0d4a15b03d329baa70d7')