# $Id$
# Maintainer:
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Chris Brannon <cmbrannon79@gmail.com>
# Contributor: JJDaNiMoTh <jjdanimoth@gmail.com>
# Contributor: Bjørn Lindeijer <bjorn lindeijer nl>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - disable sse

pkgname=dumb
pkgver=2.0.2
pkgrel=1
pkgdesc='IT, XM, S3M and MOD player library'
arch=('x86_64' 'i686')
license=('custom:dumb' 'GPL')
url='http://dumb.sourceforge.net/'
makedepends=('cmake')
depends=('glibc')
source=($pkgname-$pkgver.tar.gz::"https://github.com/kode54/dumb/archive/$pkgver.tar.gz")
sha256sums=('9e64eff5e4237a1e3c2cf2e8d5f75e3b54c2197fd5bc85a71a4741a5fd9c10f4')

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_SHARED_LIBS=ON \
    -DBUILD_ALLEGRO4=OFF \
    -DBUILD_EXAMPLES=OFF \
    -DUSE_SSE=OFF
  make
}

package() {
  cd build

  make DESTDIR="$pkgdir" install
  install -Dm644 ../$pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}