# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor:  TDY <tdy@archlinux.info>
# Contributor: Rémy Oudompheng <oudomphe@clipper.ens.fr>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - rm -fr "$pkgdir"/usr/lib/gap/pkg/digraphs-*/bin/lib/ for aarch64

pkgbase=gap
pkgname=(gap gap-doc gap-packages)
pkgver=4.10.2
pkgrel=11
pkgdesc="Groups, Algorithms, Programming: a system for computational discrete algebra"
arch=(x86_64)
url="https://www.gap-system.org/"
license=(GPL)
source=("https://www.gap-system.org/pub/gap/gap-${pkgver%.*}/tar.gz/gap-$pkgver.tar.gz" gap.sh
         libsemigroups-1.0.patch
         git+https://github.com/gap-packages/NormalizInterface#commit=cd69a42
         normalizinterface-missing-include.patch
         gap-polymake-4.0.patch)
sha256sums=('11175bed0234101643d510d4ab94c44db30bd303bfe63d86b9b86ae67cff9e49'
            '143fb8a79a52c007903cce13407850df309ef803a9b00398d05169355917de46'
            'ccd95de4f48d26b73d6df7c1847855f68ee70644d130d32f14213988c3e286e3'
            'SKIP'
            '2410dfc69f1f4d2f320e91590d55e59c7b557637f9f60b9e609b318cfc21c181'
            'e3f6d671c8df9acb6143a7c279391957967cd44f0a00b949323401d5b54ed685')
makedepends=(libxaw givaro mpfi normaliz polymake boost libsemigroups c-xsc zeromq fplll wget chrpath fmt git)

prepare() {
  cd gap-$pkgver

# Use system normaliz
  sed -e '/build-normaliz.sh/d' -i bin/BuildPackages.sh
# Use system libsemigroups
  sed -e 's|test "$with_external_libsemigroups" = yes|true|' -i pkg/semigroups-*/configure
# Disable anupq package, it's i686 only
  rm -r pkg/anupq-*
# Fix https://bugs.archlinux.org/task/55174
  sed -e '/xgap/d' -i pkg/sonata-*/PackageInfo.g
  sed -e '/XGAP/d' -i pkg/cryst/PackageInfo.g

# Update NormalizInterface to support recent normaliz
  rm -r pkg/NormalizInterface-1.0.2
  cp -r ../NormalizInterface pkg
  cd pkg/NormalizInterface
  patch -p1 -i "$srcdir"/normalizinterface-missing-include.patch

  cd ../semigroups-*
  patch -p1 -i "$srcdir"/libsemigroups-1.0.patch # Fix build with libsemigroups 1.0
  cd ../PolymakeInterface-*
  patch -p2 -i "$srcdir"/gap-polymake-4.0.patch # Fix build with polymake 4.0
}

build() {
  cd gap-$pkgver
  ./configure --prefix=/usr --with-gmp=system

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
  make libgap.la

  # Install libgap so we can link packages against it
  mkdir -p tmp-install
  libtool --mode=install install libgap.la "$srcdir"/gap-$pkgver/tmp-install

  cd pkg
  export CXXFLAGS+=" -I/usr/include/cxsc" # Find c-xsc headers
  export LDFLAGS+=" -L$srcdir/gap-$pkgver/tmp-install -lgap" # See https://trac.sagemath.org/ticket/27372
  export LD_LIBRARY_PATH="$srcdir"/gap-$pkgver/tmp-install
  export MAKEFLAGS="-j1"
  ../bin/BuildPackages.sh
}

_standardpkgs=(GAPDoc-* primgrp-* SmallGrp-* transgrp atlasrep autpgrp-* alnuth-* crisp-* ctbllib FactInt-* fga irredsol-* laguna-*
               polenta-* polycyclic-* resclasses-* sophus-* tomlib-*)

package_gap() {
  depends=(gmp zlib)
  optdepends=('gap-packages: extra packages' 'gap-doc: documentation')
  conflicts=(libgap)
  replaces=(gap-data libgap gap-4.8 gap-4.8-data)
  cd gap-$pkgver

  install -Dm644 src/*.h -t "$pkgdir"/usr/include/gap
  install -Dm644 gen/config.h -t "$pkgdir"/usr/include/gap
  install -Dm644 src/hpc/*.h -t "$pkgdir"/usr/include/gap/hpc

  install -d "$pkgdir"/usr/lib
  libtool --mode=install install libgap.la "$pkgdir"/usr/lib

  mkdir -p "$pkgdir"/usr/{bin,lib/gap/pkg}
  cp -r grp lib "$pkgdir"/usr/lib/gap
  for _pkg in ${_standardpkgs[@]}; do
    cp -r pkg/$_pkg "$pkgdir"/usr/lib/gap/pkg
  done
  install -Dm755 gap -t "$pkgdir"/usr/lib/gap
# Install launcher script
  install -Dm755 "$srcdir"/gap.sh "$pkgdir"/usr/bin/gap

  mkdir -p "$pkgdir"/usr/share
  ln -s /usr/lib/gap -t "$pkgdir"/usr/share # expected by sagemath
}

package_gap-doc() {
  depends=(gap)
  replaces=(gap-4.8-doc)
  pkgdesc="Documentation for GAP"
  cd gap-$pkgver

  mkdir -p "$pkgdir"/usr/lib/gap
  cp -r doc "$pkgdir"/usr/lib/gap
}

package_gap-packages() {
  depends=(gap)
  replaces=(gap-4.8-packages)
  optdepends=('normaliz: Normaliz interface package' 'libxaw: xgap package' 'c-xsc: float package' 'mpfi: float package'
              'libmpc: float package' 'fplll: float package' 'zeromq: ZeroMQ interface package' 'planarity: digraph package'
              'curl: curl interface package' 'libsemigroups: semigroups package' 'polymake: Polymake interface package')
  pkgdesc="Extra packages for GAP"
  cd gap-$pkgver

  mkdir -p "$pkgdir"/usr/{bin,lib/gap}
  cp -r pkg "$pkgdir"/usr/lib/gap

# fix xgap launch script
  sed -e 's|/build/gap/src/gap-4.10.2|/usr/lib/gap|g' -e 's|^GAP=.*|GAP=/usr/lib/gap/gap|g' \
    "$pkgdir"/usr/lib/gap/pkg/xgap-*/xgap.sh > "$pkgdir"/usr/bin/xgap
  chmod 755 "$pkgdir"/usr/bin/xgap
  rm "$pkgdir"/usr/lib/gap/pkg/xgap-*/xgap.sh*

# provided by main gap package
  for _pkg in ${_standardpkgs[@]}; do
    rm -r "$pkgdir"/usr/lib/gap/pkg/$_pkg
  done

# fix RPATH
  find "$pkgdir"/usr/lib/gap/pkg/ -name '*.so' | xargs chrpath -d

# remove bundled planarity
  rm -fr "$pkgdir"/usr/lib/gap/pkg/digraphs-*/bin/lib/

# remove leftover binaries and source files
  find "$pkgdir"/usr/lib/gap/pkg -name .libs -o -name '*.o' | xargs rm -fr
  find "$pkgdir"/usr/lib/gap/pkg -type d -name src | xargs rm -fr
  rm -fr "$pkgdir"/usr/lib/gap/pkg/log
}