# Maintainer: Antonio Rojas <arojas@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - disable distcc, fails to build with it
#  - add LDFLAGS and CXXOPT to lower RAM usage
#  - make -j2 due to RAM constraints

highmem=1

pkgname=polymake
pkgver=3.0r2
pkgrel=1
pkgdesc="Open source software for research in polyhedral geometry"
arch=(i686 x86_64)
url="https://polymake.org/"
license=(GPL)
options=('!distcc')
depends=(gmp perl-xml-writer perl-xml-libxml perl-xml-libxslt perl-term-readline-gnu)
makedepends=(normaliz cddlib lrs bliss-graphs ppl apache-ant singular boost)
optdepends=('singular: ideal library' 'ppl: polytope library' 'java-runtime: java module')
source=("https://polymake.org/lib/exe/fetch.php/download/polymake-$pkgver-minimal.tar.bz2")
md5sums=('c1f5d71cdd86d0339c3e642494d6ac67')

prepare() {
  cd polymake-3.0
# fix lrs headers location
  sed -e 's|lrslib.h|lrslib/lrslib.h|g' -i bundled/lrs/apps/polytope/src/lrs_interface.cc \
      -i bundled/group/external/sympol/sympol/raycomputationlrs.cpp
  sed -e 's|<lrslib.h>|<lrslib/lrslib.h>|g' -e 's|\$lrs_path\/include|$lrs_path/include/lrslib|g' -i bundled/lrs/configure.pl
# fix singular detection
  sed -e 's|lresources|lsingular_resources|g' -i bundled/singular/configure.pl
}

build() {
  cd polymake-3.0
  LDFLAGS+=" -Wl,--no-keep-memory -Wl,--reduce-memory-overheads"
  ./configure --prefix=/usr CXXOPT="-O1"
  make -j2
}

package() {
  cd polymake-3.0
  make DESTDIR="$pkgdir" install
}