# $Id: PKGBUILD 143721 2011-11-28 17:06:53Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Kritoke <kritoke@gamebox.net>
# Contributor: jlvsimoes <jlvsimoes@oninet.pt>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - fix_build_system.patch to use libtool for compilation
#  - removed making libcryptopp.so, adjusted packaging for .libs

plugrel=1

pkgname=crypto++
pkgver=5.6.1
_srcver=561
pkgrel=4
pkgdesc="A free C++ class library of cryptographic schemes"
arch=('i686' 'x86_64')
url="http://www.cryptopp.com/"
license=('custom')
depends=('gcc-libs')
makedepends=('unzip')
source=("http://www.cryptopp.com/cryptopp${_srcver}.zip"
        'libcrypto++.pc'
        'fix_build_system.patch'
        'gcc4.7.patch')
md5sums=('96cbeba0907562b077e26bcffb483828'
         '2337c6edbc552d9142cae8e0854715e7'
         '31489843fb50d5ea2250855098f87983'
         '8d454c524bafc05aa842ddfc63d8431d')

build() {
  cd ${srcdir}

  # ALARM
  patch -p0 -i fix_build_system.patch

  # Fix gcc 4.7 build
  patch -Np1 -F3 -i "${srcdir}/gcc4.7.patch"

  sed -i -e 's/^CXXFLAGS/#CXXFLAGS/' GNUmakefile
  export CXXFLAGS="${CXXFLAGS} -DNDEBUG -fPIC"
  make -f GNUmakefile  
}

package() {
  cd ${srcdir}

  install -d ${pkgdir}/usr/{lib/pkgconfig,include/cryptopp}
  install -m644 *.h ${pkgdir}/usr/include/cryptopp/
  install -m644 .libs/libcryptopp.a "${pkgdir}/usr/lib/libcryptopp.a"
  install -m644 .libs/libcryptopp.so "${pkgdir}/usr/lib/libcryptopp.so"
  install -m644 ${srcdir}/libcrypto++.pc "${pkgdir}/usr/lib/pkgconfig/libcrypto++.pc"
  install -D -m644 License.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}