# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Kerrick Staley <mail@kerrickstaley.com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch to fix build on ARM

pkgname=pyzy
pkgver=1.0
_commit="d7747466562cb8b4bc2934708e29b7643c7bedbc"
pkgrel=6
pkgdesc='The Chinese PinYin and Bopomofo conversion library'
arch=('x86_64')
url='https://github.com/pyzy/pyzy'
license=('LGPL')
depends=('glib2' 'sqlite' 'util-linux')
makedepends=('git' 'doxygen' 'gnome-common' 'python')
source=("git://github.com/pyzy/pyzy.git#commit=$_commit"
        pyzy-python3.patch
        pyzy-0.1.0-fixes-compile.patch)
sha512sums=('SKIP'
            '901900d6b7f40bd9910bb7a200dcb53096169cc6501d0ab34faf25b3e279b8dd0f41702bb48c9554803d2089ab43f245ca7ba98137462572f7625fb7992ec618'
            '973f1d9928801e028fe8a212403ec421a0fcbb9874745dd6722b1a769d8c9717d5ae88fb62d3fea6d0fc60c6889f3fa9cf17600d5eafcad8fb6b9f28e2677098')

prepare() {
  cd $pkgname
  patch -p1 -i ../pyzy-0.1.0-fixes-compile.patch
}

build() {
  cd $pkgname
  patch -p1 -i ../pyzy-python3.patch

  ./autogen.sh --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "$srcdir/$pkgname"

  make DESTDIR="$pkgdir" install
}