# Maintainer: Kevin Mihelich <kevin@archlinuxarm.org
# Contributor: Justin Settle <jus10 at partlycloudy dot org>

buildarch=12

pkgname=vboot-utils
pkgver=r1739.1919b169b
pkgrel=1
arch=('armv7h' 'aarch64')
pkgdesc="Chromium OS vboot utilities"
url="https://chromium.googlesource.com/chromiumos/platform/vboot_reference/+/master"
license=('custom:chromiumos')
makedepends=('libyaml' 'git')
provides=('cgpt')
replaces=('cgpt')
source=("git+https://chromium.googlesource.com/chromiumos/platform/vboot_reference")
md5sums=('SKIP')

pkgver() {
  cd vboot_reference
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd vboot_reference
  # OpenSSL 1.1 fix: https://chromium-review.googlesource.com/c/461901/
  git cherry-pick -n ad9ba0ea32f92cc37a21b8c3c45e08408af1a4b7
  # remove -Werror to prevent build failure
  sed -i 's/-Werror//g' Makefile
}

build() {
  cd vboot_reference
  ARCH=arm make V=1
}

package() {
  cd vboot_reference
  make DESTDIR="${pkgdir}/usr" install
}